Lookup unique ID and insert date into next column - excel

Question

I Have a table that is set out with these headers:
Task ID | Description | Date completed | Time completed
Let say that the table is set out so that Task ID is in cell A3, Description B3, Date Completed C3, and Time Completed D3. In cell A1 I will input the Task ID to be looked up.
What I would like to happen is that when the macro is run, the Task ID entered into cell A1 is found in the table and then the date and time (at the time of running the Macro) are entered into the corresponding cells in columns C and D.
Thanks!

Answer 1

It sounds like you just need a bunch of VLOOKUPS. In cell A1 enter your task ID. In cell A2 enter a VLOOKUP for the description (Assuming you have 100 Ids)
=VLOOKUP($A$1,$A$4:$D$100,2,FALSE)
and in A3 for the Date etc
=VLOOKUP($A$1,$A$4:$D$100,3,FALSE)

Answer 2

The following two procedures represent one way to do what you are interested in. The first uses the FIND function to locate the task ID in your table that matches the contents of cell A1; the second runs the first procedure whenever you make an entry in A1.
Date and time logging code
You will need to paste this code into a standard VBA module in the workbook. A standard code module can be inserted by selecting Visual Basic from the Developer tab of the ribbon, and then choosing Insert, Module on the main menu of the VBA code editor.
Note that the procedure assumes that the task table is in Sheet1 of the workbook. If it is in another sheet, you will need to change the name "Sheet1" in the code to the correct name.
Sub LogTaskCompletion()
Dim lastRow As Long
Dim foundCell As Range
With ThisWorkbook.Sheets("Sheet1") '<-- change sheet name here
If Not .Range("A1").Value = "" Then
lastRow = .Range("A" & Rows.Count).End(xlUp).Row
'do the search
Set foundCell = .Range("A2:A" & lastRow).Find(What:=.Range("A1").Value, _
LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows)
If Not foundCell Is Nothing Then
'a match! post the date and time for the task
With foundCell
.Offset(0, 2).Value = Date
.Offset(0, 2).NumberFormat = "mm-dd-yyyy"
.Offset(0, 3).Value = TimeValue(Now())
.Offset(0, 3).NumberFormat = "hh:mm am/pm"
End With
Else
'no match!
MsgBox "Cannot find task " & .Range("A1").Value
End If
.Range("A1").ClearContents
End If
End With
End Sub
Macro trigger code
This procedure will run the preceding macro whenever an entry is made in A1.
It needs to be installed as code private to the worksheet the task table is in. The easiest way to do this is to right-click on the worksheet's tab, select View Code, and then paste the code into the editor pane that pops up.
Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("A1")) Is Nothing Then
Exit Sub
End If
Application.EnableEvents = False
LogTaskCompletion
Application.EnableEvents = True
End Sub
After installing the code, save the file as an macro-enabled ("xlsm") workbook.

Answer 3

It can be achieved with combination of Worksheet_Change and Vlookup. Kindly put this code in sheet code section.
Once the value is entered in A1 the macro is triggered and if the values is found in the table it gets the corresponding values (description) using Vlookup. Also it enters the current date & time.
Private Sub Worksheet_Change(ByVal Target As Range)
On Error Resume Next
Application.EnableEvents = False
If Not Intersect(Target, Range("A1")) Is Nothing Then
Dim lastRow As Long, tblRng As Range
lastRow = Range("A" & Rows.Count).End(xlUp).Row
If lastRow <= 3 Then lastRow = 3
Set tblRng = Range("A3:D" & lastRow)
dt = Application.VLookup(Target, tblRng, 1, 0)
If Not IsError(dt) Then
With Target
.Offset(0, 1).Value = Application.VLookup(Target, tblRng, 2, 0)
.Offset(0, 2).Value = Date
.Offset(0, 2).NumberFormat = "mm/dd/yyyy"
' if you want date from tbl use Application.VLookup(Target, tblRng, 3, 0)
.Offset(0, 3).Value = TimeValue(Now())
.Offset(0, 3).NumberFormat = "hh:mm am/pm"
' if you want date from tbl use Application.VLookup(Target, tblRng, 4, 0)
End With
Else
With Target
.Offset(0, 1).Value = vbNullString
.Offset(0, 2).Value = vbNullString
.Offset(0, 3).Value = vbNullString
End With
End If
End If
Application.EnableEvents = True
End Sub