create hyperlink in visual basic excel between worksheets - excel

Question

When I used this formula,
Sub IndexingSheets()
Sheets(1).Range("B3").Formula = _
"=HYPERLINK(""#" & ThisWorkbook.Sheets(2).Name & "!A5"", ""TextToDisplay"")"
Sheets(2).Range("A5").Formula = _
"=HYPERLINK(""#" & ThisWorkbook.Sheets(1).Name & "!B3"", ""TextToDisplay"")"
End Sub
it creates a hyperlink but when I click it, it shows reference is not valid. Then when I changed the formula in the formula bar, I added the filename and it worked so it will now look like this:
=HYPERLINK("[Book1.xls]'Sheet2 123!A5", "gg")
But originally it is just like this:
=HYPERLINK("#Sheet2 123!G20", "gg")
How can I alter my original code which I shown on the topmost so that this:
=HYPERLINK("[Book1.xls]'Sheet2 123!A5", "gg")
will be shown or will be the format in the formula bar? my problem is how can i put the filename now without just copying the filename itself and not just pasting it in the code?
I just want to clarify that there's a messagebox that says you should input the 2nd name of the sheet. so the name of the sheet is not just "Sheet2" anymore.
For instance you put in the msgbox "123", the name of the sheet would now become "Sheet2 123". the messagebox is already present, no need to create a code for it.

Answer 1

Try this. You need to put single-quotes around the sheet names, to account for the possible spaces in sheet names. If you omit single-quotes, then the sheet names must not contain any spaces.
Sub IndexingSheets()
With ThisWorkbook
.Sheets(1).Range("B3").Formula = _
"=HYPERLINK(""#'" & .Sheets(2).Name & "'!A5"", ""Jump to Sheet2!A5"")"
.Sheets(2).Range("A5").Formula = _
"=HYPERLINK(""#'" & .Sheets(1).Name & "'!B3"", ""Jump to Sheet1!B3"")"
End With
End Sub
To include the Workbook name (not necessary, I don't think):
Sub IndexingSheets()
With ThisWorkbook
.Sheets(1).Range("B3").Formula = _
"=HYPERLINK(""#'[" & .Name & "]" & .Sheets(2).Name & "'!A5"", _
""Jump to Sheet2!A5"")"
.Sheets(2).Range("A5").Formula = _
"=HYPERLINK(""#'[" & .Name & "]" & .Sheets(1).Name & "'!B3"", _
""Jump to Sheet1!B3"")"
End With
End Sub
And, an alternate method of achieving the same -- this one includes the Workbook name, too:
Sub IndexingSheetsWithFileName()
With ThisWorkbook
.Sheets(1).Hyperlinks.Add Anchor:=.Sheets(1).Range("B3"), _
Address:="", SubAddress:= _
"'[" & .Name & "]" & .Sheets(2).Name & "'!A5", _
TextToDisplay:="Jump to Sheet2!A5"
.Sheets(2).Hyperlinks.Add Anchor:=.Sheets(2).Range("A5"), _
Address:="", SubAddress:= _
"'[" & .Name & "]" & .Sheets(1).Name & "'!B3", _
TextToDisplay:="Jump to Sheet1!B3"
End With
End Sub