Excel list, 2000 rows to 250 page templates - excel

Question

Unfortunately i am not a master of excel. I have 2000 rows of information that i must fill out manually. Then i use vlookup to sort them into sheets with a template that can be printed out. My problem is i cannot find a way to make the vlookup less manual. I am hoping i can be helped to find a way not to manually add 250 sheets and do the vlookup for each of the 2000 rows of information.
Is it possible to add a new sheet automatically or even tell the vlookup to look at the next row, like an index would with php/mysql?
Any help is appreciated.
This is a working example of what i am trying to achieve.

Answer 1

There are a variety of ways of solving this. I got the following to work.
Note: this assumes you start with one sheet in your s/sheet that has the main data list starting in A1
See if this works for you...
Sub ParseData()
Dim Entries As Range, entry As Range, cnt As Integer, rowID As Integer, col As Integer, rw As Integer
Set Entries = Worksheets(1).Range("A2:A" & Worksheets(1).Range("A2").End(xlDown).Row)
cnt = 0
rowID = 0
For Each entry In Entries
cnt = cnt + 1
If cnt = 1 Or cnt Mod 10 = 1 Then
Worksheets.Add After:=Worksheets(Worksheets.Count)
rowID = 1
End If
With Worksheets(Worksheets.Count)
col = IIf(rowID <= 5, 1, 6)
rw = IIf(rowID <= 5, rowID, rowID - 5)
.Cells.HorizontalAlignment = xlCenter
.Cells((8 * rw - 7), col) = "Plan#"
.Cells((8 * rw - 7), col + 1) = entry
.Cells((8 * rw - 7), col + 2) = "Vol#"
.Cells((8 * rw - 7), col + 3) = entry.Offset(0, 2)
With .Range(.Cells((8 * rw - 7), col), .Cells((8 * rw - 7), col + 3))
.Font.Bold = True
.Borders(xlEdgeBottom).LineStyle = xlContinuous
End With
.Cells((8 * rw - 7) + 2, col) = "To:"
.Cells((8 * rw - 7) + 2, col + 1) = entry.Offset(0, 3)
.Cells((8 * rw - 7) + 4, col) = "Date:"
.Cells((8 * rw - 7) + 4, col + 1) = entry.Offset(0, 4)
.Cells((8 * rw - 7) + 4, col + 1).NumberFormat = "m/d/yyyy"
rowID = rowID + 1
End With
Next entry
End Sub