Remove empty rows - excel

Question

I have an Excel macro that removes all the empty rows in an Excel sheet. This macro takes too long to finish. The files are generated automatically and every file needs to run this macro. The macro deletes one row at a time after checking its value.
I need something like this:
If rowValue = "" then
deleteThisRow And deleteAll Subsequent rows at once
End If
This is the code I am using now:
Sub RemoveRows()
Range("A8").Select
Dim checkval
Dim RowAmount
RowAmount = 93
Do
checkval = ActiveCell.Value
If (checkval = "") Then
ActiveCell.EntireRow.Delete
Else
ActiveCell.Offset(1, 0).Select
End If
RowAmount = RowAmount - 1
Loop While RowAmount > 0
End Sub

Answer 1

Your idea to delete all necassary rows in one operation is bang on. In addition avoiding Select and avoiding looping over a range of cells will speed thing up too.
Here's an approach that should work for you
Sub Demo()
Dim sh As Worksheet
Dim rng As Range
Dim rngBlanks As Range
' Get a reference to the sheet you want to process
Set sh = ActiveSheet
' Get a reference to the range of cells to test
With sh
Set rng = .Range(.Cells(8, 1), .Cells(.Rows.Count, 1).End(xlUp))
End With
' if there are no blanks SpecialCells will error, so handle it
On Error Resume Next
' Reduce rng to reference only blank cells
Set rngBlanks = rng.SpecialCells(xlCellTypeBlanks)
On Error GoTo 0
' see if there are any blanks
If Not rngBlanks Is Nothing Then
' delete all of them
rngBlanks.EntireRow.Delete
End If
End Sub
Update based on additional info provided: "blank" cells may contain formulas returning an empty string.
Here's an approach using AutoFilter
Sub Demo()
Dim sh As Worksheet
Dim rng As Range
Dim rngBlanks As Range
Application.ScreenUpdating = False
' Get a reference to the sheet you want to process
Set sh = ActiveSheet
' Get a reference to the range of cells to test, plus header row
With sh
Set rng = .Range(.Cells(7, 1), .Cells(.Rows.Count, 1).End(xlUp))
End With
' Apply filr to hide non-empty cells
sh.AutoFilterMode = False
rng.AutoFilter Field:=1, Criteria1:="=", VisibleDropDown:=True
' if there are no blanks SpecialCells will error, so handle it
On Error Resume Next
' Reduce rng to reference only blank cells, exclude header row
Set rngBlanks = rng.Offset(1, 0).SpecialCells(xlCellTypeVisible)
On Error GoTo 0
' see if there are any blanks
If Not rngBlanks Is Nothing Then
' delete all of them
rngBlanks.EntireRow.Delete
End If
sh.AutoFilterMode = False
Application.ScreenUpdating = True
End Sub

Answer 2

So basically, if it comes across a blank row, it should delete that row and all the rows below it.
For deleting all the rows below, you could essentially do the same thing that happens when you press CTRL and the down arrow - it goes to either the next value down (if there is one, and in your case it sounds like there won't be) or to the end (row 65536 is the limit in all the Excel versions I've come across). Which would be...
Range(Selection, Selection.End(xlDown)).Select
Selection.Delete Shift:=xlUp
This will go from the row you've selected (so no need to delete it), down to either the next value or the end, and delete all those rows.
EDIT - entire macro:
Dim i As Integer
For i = 1 To 93
Range("A" & i).Select
Dim CheckVal As String
CheckVal = ActiveCell.Value
If (CheckVal = "") Then
Range(Selection, Selection.End(xlDown)).Select
Selection.Delete Shift:=xlUp
End If
Next i
Bear in mind though that, if there ARE any values below the first "blank" that is found, they are deleted too as the first contiguous value.