Reporting Row and Column Names Connected to a Value (Microsoft Access) - excel

Question

I'm well out of my depth on this one, as I don't use databases much. I hope it suffices that I've tried to pay it forward by helping people with InDesign and Photoshop on other websites!
I can use Access or Excel for what follows.
I have data that looks like:
year President Vice
1980 Reagan Bush Sr.
1984 Reagan Bush Sr.
1988 Bush Sr. Quayle
1992 Clinton Gore
1996 Clinton Gore
2000 Bush Jr. Cheney
2004 Bush Jr. Cheney
2008 Obama Biden
2012 Obama Biden
I want a report that looks like:
Biden: Vice 2008, 2012
Bush Jr.: President 2000, 2004
Bush Sr.: President 1988; Vice 1980, 1984
Cheney: Vice 2000, 2004
Clinton: President 1992, 1996
Gore: Vice 1992, 1996
Obama: President 2008, 2012
Quayle: Vice 1988
Reagan: President 1980, 1984
I'm having trouble figuring out how to identify a common name that may appear anywhere on the table, and how to grab the row and column labels for the report.
This is a simplified version of the real data, which doesn't have to do with politicians. There are actually ten column labels that are relevant, not just two. "Bush Sr." gives an example of one person holding two different offices.
There are not currently any cases where the same name appears in two different columns in the same row, but I'd prefer not to rule out the possibility, unless it's dramatically more complex to allow that.
Thanks!

Answer 1

The first thing we need to do is convert that data from "few rows, many columns" to "few columns, many rows" via a UNION query. (I saved your test data in a table called [N_column_table].)
SELECT [year], "President" AS office, [President] AS person
FROM [N_column_table]
UNION ALL
SELECT [year], "Vice" AS office, [Vice] AS person
FROM [N_column_table]
If you save that query as "3_column_data" then you can use it just like a table in other queries, reports, etc.. (You will have to add ~8 more UNION ALL constructs when you build your query for the real data.)
So now our data looks like this
year office person
1980 President Reagan
1984 President Reagan
1988 President Bush Sr.
1992 President Clinton
1996 President Clinton
2000 President Bush Jr.
2004 President Bush Jr.
2008 President Obama
2012 President Obama
1980 Vice Bush Sr.
1984 Vice Bush Sr.
1988 Vice Quayle
1992 Vice Gore
1996 Vice Gore
2000 Vice Cheney
2004 Vice Cheney
2008 Vice Biden
2012 Vice Biden
Now, as for "gluing together" the offices and years, we'll need to use a little VBA function for that. Create a Module in Access, and paste in the following code
Public Function ListTerms(person As String) As String
Dim cdb As DAO.Database
Dim rstOffice As DAO.Recordset, rstYear As DAO.Recordset
Dim result As String, yearString As String
Const YearSeparator = ", "
Const OfficeSeparator = "; "
Set cdb = CurrentDb
result = ""
Set rstOffice = cdb.OpenRecordset( _
"SELECT DISTINCT office " & _
"FROM 3_column_data " & _
"WHERE person=""" & Replace(person, """", """""", 1, -1, vbBinaryCompare) & """ " & _
"ORDER BY 1")
Do While Not rstOffice.EOF
yearString = ""
Set rstYear = cdb.OpenRecordset( _
"SELECT DISTINCT [year] " & _
"FROM 3_column_data " & _
"WHERE person=""" & Replace(person, """", """""", 1, -1, vbBinaryCompare) & """ " & _
"AND office=""" & Replace(rstOffice!Office, """", """""", 1, -1, vbBinaryCompare) & """ " & _
"ORDER BY 1")
Do While Not rstYear.EOF
If Len(yearString) > 0 Then
yearString = yearString & YearSeparator
End If
yearString = yearString & rstYear!Year
rstYear.MoveNext
Loop
rstYear.Close
Set rstYear = Nothing
If Len(result) > 0 Then
result = result & OfficeSeparator
End If
result = result & rstOffice!Office & " " & yearString
rstOffice.MoveNext
Loop
rstOffice.Close
Set rstOffice = Nothing
Set cdb = Nothing
ListTerms = result
End Function
Now we can use that function in a query to list each person and their terms in office
SELECT personlist.[person], ListTerms(personlist.[Person]) as terms
FROM (SELECT DISTINCT person FROM 3_column_data) personlist
which returns
person terms
Biden Vice 2008, 2012
Bush Jr. President 2000, 2004
Bush Sr. President 1988; Vice 1980, 1984
Cheney Vice 2000, 2004
Clinton President 1992, 1996
Gore Vice 1992, 1996
Obama President 2008, 2012
Quayle Vice 1988
Reagan President 1980, 1984