Searching multiple worksheets from an excel 2007 function - excel

Question

I have worksheets A, B and C. Worksheet A contains a column with dates. B and C each contain two columns: one with a date and one with a value. For example
worksheet A:
A B
1 2001-01-01 ---
2 2001-01-02 ---
worksheet B:
A B
1 2001-01-01 1
worksheet C:
A B
1 2001-01-02 2
I'd like to have a function =Search(W, date) that when run from worksheet A returns a value assigned to date in worksheet W. For example Search(C, "2001-01-02")=2.
This is an abstract version of searching for currency rates at given dates: multiple worksheets contain rates for currencies, so when we search, we know what worksheet (currency) to pick.
How to define such a function? I tried passing parameters to a custom macro, but excel keeps giving me cryptic errors. It's seems easy to use a macro that uses the selected cell as a source, but a function would be better.
EDIT: my attempt, doesn't work
Function FindRate()
Dim FindString As String
Dim Rate As String
Dim Src As Range
Dim Found As Boolean
MsgBox sheet_name
Rate = "Not found "
Set Src = Application.ActiveCell
FindString = "2006-12-19"
Sheets("cur CHF").Activate
Found = False
For Each c In [A1:C2000]
If c.Value = FindString Then
Rate = c.Offset(0, 1).Value
Found = True
Exit For
End If
Next
MsgBox Rate
'FindRate = Rate
End Function
Function Rate(cname As String)
Dim sheet_name As String
Dim c2s As New Collection
c2s.Add "cur worksheet name", "cur"
sheet_name = c2s.Item(cname)
Call FindRate(sheet_name)
End Function

Answer 1

What you are really doing is a lookup. There is a VLOOKUP function built into Excel that will do exactly what you want. The syntax is
VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])
This will look up the value lookup_value in the table table_array. It will find an exact match in the first column if range_lookup is false, otherwise it will find the closest value (faster, but data must be sorted).
It will return the value in the col_index_num column.
In your case, if you want the value from sheet B corresponding to "2012-01-01", you would do
=VLOOKUP("2012-01-01", Sheet2!A2:B1000, 2, false)
You may have to mess around with converting the date string into a date value, etc. If you had added the values on Sheet2 as dates, you would want to use
=VLOOKUP(DATEVALUE("2012-01-01"), Sheet2!A2:B1000, 2, false)
since that function correctly converts the string "2012-01-01" to something Excel recognizes as a DATE.
Now if you don't know a priori which sheet you will need to access (because that's a variable), you may have to write yourself a VBA function:
Function myLookup(value, curr)
Dim dval As Long, luTable As Range, s As Worksheet, c As Range
' if user types date as string, convert it to date first...
If VarType(value) = vbString Then
dval = DateValue(value) ' this doesn't work if dval hasn't been declared as `long`!
Else
dval = value
End If
' see if `curr` is the name of a defined range; if so, use it
On Error GoTo notArange
' if the next line doesn't generate an error, then the named range exists:
Set luTable = Range(curr)
' so let's use it...
GoTo evaluateFunction
notArange:
' If we got here, "curr" wasn't the name of a range... it must be the name of a sheet
' first, tell VBA that we're done handling the last error:
Resume here
here:
On Error GoTo noSheet
Set s = ActiveWorkbook.Sheets(curr)
Dim firstCell As Range, lastCell As Range
Set firstCell = s.Range("a1")
Set lastCell = s.Range("b1").End(xlDown) ' assuming data in columns A and B, and contiguous
Set luTable = Range(firstCell, lastCell)
evaluateFunction:
myLookup = Application.WorksheetFunction.VLookup(dval, luTable, 2, False)
Exit Function
noSheet:
' get here if currency not found as either sheet or range --> return an error message
myLookup = curr & " not found!"
End Function
This has been tested on a small sample, and it worked. A few things to note:
You can name the range where the conversion is kept ("euro", "dinar", "yen", ...) instead of keeping each on a separate sheet. You can then pass the name of the range (make it the same as the name of the currency for convenience) as a parameter to your function, and access it with Range(currency). This also gets around the problem of "hard-wiring" the size of the range
The function will check for the existence of a named range, and use it if it exists. If it doesn't, it will look for a sheet with the correct name
If you use an "invalid currency name", this will be reflected in the return value (so myLookup("01-01-2012", "Florins") will return "Florins not found!"
Instead of assuming a lookup table of a certain length, I determine the size of the table dynamically, using the End(xlDown) construct
I allow date to be passed in as a String, or as a DATEVALUE. The function notices the string and converts it
Right now I am setting the range_lookup parameter to False. This means that there must be an exact match, and values that are not present will generate errors. If you prefer to return "the best match", then you set the parameter to True. Now the risk is that you will return garbage when the date requested is outside of your limits. You could solve this by setting the first and last value of the exchange rate column to "no valid data". When the lookup function returns, it will show this value.

Answer 2

This is a simple FindCell function I use a lot is simply extends Excels search function but from what you have got should suit fine. It returns a range however it is simple enough to get the value from the return range. I use it as follows (with comments added for your sake):
Function FindCell(SearchRange As Range, SearchText As Variant, OffsetDown As Integer, OffsetRight As Integer) As Range
'Do a normal search range call using the passed in range and text.
'First try looking formula
Set FindCell = SearchRange.Find(What:=SearchText, LookAt:=xlWhole, LookIn:=xlFormulas, _
MatchCase:=True, SearchOrder:=xlByRows).Offset(OffsetDown, OffsetRight)
'If nothing is found then look in values
If FindCell Is Nothing Then
Set FindCell = SearchRange.Find(What:=SearchText, LookAt:=xlWhole, LookIn:=xlValue, _
MatchCase:=True, SearchOrder:=xlByRows).Offset(OffsetDown, OffsetRight)
End If
End Function
This can be used a function for the rate (you could of course combine the two functions but I use FindCell for many applications so have kept it seperate):
Function GetRate(sWorksheetName As String, theDate As Date) As Double
Dim returnRange As Range
'Call the FindCell function specifying the range to search (column A), and the date and then offset one cell to the right for the value
Set returnRange = FindCell(ThisWorkbook.Worksheets(sWorksheetName).Columns("A:A"), sDate, 0, 1)
'Check if we've found something. If its Nothing then we haven't
If Not returnRange Is Nothing Then GetRate = returnRange.Value
End Function
You can test it in a Sub like so:
Sub Test()
MsgBox "Value is " & GetRate("Sheet2", "2001-01-01")
End Sub
By accepting the GetRate as a date type it shouldn't matter what format the date is in the worksheet.