On click search and go cell in workbook - search

Question

I would like to know if anyone can help me on this one.
I have a workbook with several tabs and a main page.
On the main page i have a top 20 of issues that are populated automatically.
What i want to do is to automatically create hyperlinks on the "number" row, and when i click them to search that number in the workbook and go to as well. Similar to the CTRL+F.
Number - Problem - Status
IM123
IM124
IM145
ETC..
can someone help me?
Thanks

Answer 1

In the Worksheet_SelectionChange event, you can use something like this to search for the data
If Not Intersect(Target, Range("A1:A4")) Is Nothing Then
If Target.Count = 1 Then
Cells.Find(What:=Target.Value, LookIn:=xlFormulas, LookAt:= _
xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
After:=ActiveCell, SearchFormat:=False).Activate
End If
End If
this moves to the next cell containing the same data as the cell you have clicked in, as long as you are in the specified range (A1:A4) and you have only selected one cell (Target.Count=1)

Answer 2

The following will search for whatever number is in the cell you have selected.
In addition to finding the first result, it will ask if you want to continue searching for the next result. That way, if you have multiple instances of an issue, you can "loop" through all of the results that are found in the worksheet. It will also ignore search results found on your MainWorksheet containing your top 20 issues. Cells.Find by itself will simply return the first result found, even if it is in the same worksheet.
It will also tell you whether or not the issue number was found in each sheet, and when all of the worksheets have been checked (in case no more results are found). If you respond that you don't want to continue searching, it will go to the first instance of the issue number that was found in the most recent worksheet that was checked.
In order to simulate a hyperlink, you need to use a worksheet event such as Intersect (described in Sean's answer) or FollowHyperlink. Personally, I prefer to use alternatives to worksheet events where possible, as they will always trigger when the condition is met, even if unintentionally. For example, you could create a shape or macro button and assign the macro to it. That way, the code will only run when the user clicks on the button.
Also, please let us know if there is more that you really want to do once you've identified the issue. For example, you could automatically make changes to related cells, or create a list of all of the instances of that issue (or all issues) that were found.
Good luck!
'Create a string variable to store the problem status
Dim StringProblemStatus As String
'Create a string variable to store the worksheet name of the main page containing the problem status
Dim StringMainWorksheet
'Create a range variable to store the results of the Find method
Dim RangeFindResults As Range
'Create an integer variable to store the current worksheet number
Dim IntegerSheetCount As Integer
'Set the variable to the problem status stored in the current cell
StringProblemStatus = Selection.Value
'Set the variable to the worksheet name containing the problem status
StringMainWorksheet = ActiveSheet.Name
'Create a For/Next loop so that the following code will evaluate all worksheets in the workbook
For IntegerSheetCount = 1 To ActiveWorkbook.Sheets.Count
Sheets(IntegerSheetCount).Activate
'Search for the problem number within the worksheet
'Check that the sheet being searched is not the MainWorksheet
If ActiveSheet.Name <> StringMainWorksheet Then
'Searches for exact matches
Set RangeFindResults = _
Cells.Find( _
What:=StringProblemStatus, _
After:=ActiveCell, _
LookIn:=xlFormulas, _
LookAt:=xlWhole, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=False, _
SearchFormat:=False _
)
'Returns a message to the user if the status is not found
If RangeFindResults Is Nothing Then
MsgBox "Problem Status " & StringProblemStatus & " was not found in worksheet " & Sheets(IntegerSheetCount).Name
Else
'Returns a message to the user if the status is found
If MsgBox("Problem Status " & RangeFindResults & " found in worksheet " & _
Sheets(IntegerSheetCount).Name & " in cell " & " " & RangeFindResults.Address & _
". Continue searching?", vbYesNo) = vbNo Then
RangeFindResults.Activate
Exit Sub
End If
End If
End If
'Move to the next worksheet
Next IntegerSheetCount
'Notify the user that all worksheets have been searched
MsgBox "All worksheets searched"
End Sub