Preventing double instance of validation error occuring - excel

Question

I'm having a problem validating three drop down's at once. Here are the test cases:
cbo_fac1 - user must select this as a pre-requisite for cbo_fac1 and cbo_fac2
cbo_fac2 - user must select cbo_fac1 as a pre-requisite
cbo_fac3 - user must select cbo_fac1 and cbo_fac2 as a pre-requisite
Here is the code I'm using so far. Unfortunately in some cases i.e. if the user tries to select cbo_fac3 first, it seems to be looping several of the errors. Is there any way I can merge these functions and have it only display the error once in each case?
Private Sub cbo_fac2_Enter()
If Len(cbo_fac1.Value) = 0 Then
MsgBox ("Please select a first preference before selecting a second preference")
cbo_fac1.SetFocus
Exit Sub
End If
End Sub
Private Sub cbo_fac3_Enter()
If Len(cbo_fac2.Value) = 0 & Len(cbo_fac3.Value) = 0 Then
MsgBox ("Please select a first preference before selecting a second/third preference")
cbo_fac1.SetFocus
Exit Sub
End If
If Len(cbo_fac2.Value) = 0 Then
MsgBox ("Please select a second preference before selecting a third preference")
cbo_fac2.SetFocus
Exit Sub
End If
End Sub

Answer 1

This approaches the problem from the other end, enabling or disabling the comboboxes based on whether the ones previous are filled in. Here the cascading events are your friend in the case of the 3rd combobox, as clearing the 1st one triggers a change in the 2nd, which clears the 3rd. Add this code to your userform:
Private Sub cbo_fac1_Change()
With cbo_fac2
.Enabled = Len(cbo_fac1.Value) > 0
If Not .Enabled Then
.ListIndex = -1
End If
End With
End Sub
Private Sub cbo_fac2_Change()
With cbo_fac3
.Enabled = Len(cbo_fac2.Value) > 0
If Not .Enabled Then
.ListIndex = -1
End If
End With
End Sub
Just a note that if you end up with a much longer series of these, you'll want to look into a WithEvents control class.
Also, as much as possible, try to avoid error messageboxes when a user enters a control. Try to either guide them with visual cues - disabled, empty controls in this case - or wait until they hit OK and then tell them what they need to change.
If anybody else wants to try this out, create a form with the 3 comboboxes, and then add this initialization code to your form:
Private Sub UserForm_Initialize()
Dim i As Long
With Me
With .cbo_fac1
For i = 1 To 10
.AddItem .Name & i
Next i
End With
With .cbo_fac2
For i = 1 To 10
.AddItem .Name & i
Next i
.Enabled = False
End With
With .cbo_fac3
For i = 1 To 10
.AddItem .Name & i
Next i
.Enabled = False
End With
End With
End Sub