Groovy writing single method insted of two each function - groovy

Question

I am a Groovy beginner
These are two each calls which both do a similar task but with a different property of s2PublicLifecycleInstance.
How can I write a separate function which does the following, so that I can have only method call to achive the task?
def scheduledStatusArray =[]
def publishedStatusArray =[]
s2PublicLifecycleInstance.each {
if(it.scheduledInMyLearnStatus == "No"){
scheduledStatusArray.add(1)
} else if(it.scheduledInMyLearnStatus == "Yes"){
scheduledStatusArray.add(2)
}else{
scheduledStatusArray.add(3)
}
}
s2PublicLifecycleInstance.each {
if(it.publishedOnTrainingClassesStatus == "No"){
publishedStatusArray.add(1)
}else if(it.publishedOnTrainingClassesStatus == "Yes"){
publishedStatusArray.add(2)
}else{
publishedStatusArray.add(3)
}
}
I want something like this:
def publishedStatusArray = functionCall(s2PublicLifecycleInstance, propertyName)
is it possible in Groovy?

Answer 1

You could use closures and currying:
def checkStatus = { prop,instances ->
def statuses = instances.collect {
switch( it[prop] ) {
case "Yes": 1
break
case "No": 2
break
default: 3
}
}
return statuses
}
def checkScheduledStatus = checkStatus.curry("scheduledInMyLearnStatus")
def checkPublishedStatus = checkStatus.curry("publishedOnTrainingClassesStatus")
def scheduledStatusArray = checkScheduledStatus(s2PublicLifecycleInstance)
def publishedStatusArray = checkPublishedStatus(s2PublicLifecycleInstance)

Answer 2

You can do it this way using a method:
List check( List lifecycle, String param ) {
lifecycle.collect { it ->
switch( it."$param" ) {
case "No":
return 1
case "Yes":
return 2
default:
return 3
}
}
}
def scheduledStatusArray = check( s2PublicLifecycleInstance, 'scheduledInMyLearnStatus' )
def publishedStatusArray = check( s2PublicLifecycleInstance, 'publishedOnTrainingClassesStatus' )
Or, you could do this (which is less code):
List check( List lifecycle, String param ) {
def retvals = [ 'No':1, 'Yes':2 ].withDefault { 3 }
lifecycle.collect { it ->
retvals[ it."$param" ]
}
}
Another alternative would be to use inject with multiple assignment:
def (scheduledStatusArray, publishedStatusArray) = s2PublicLifecycleInstance.inject( [[],[]] ) { lists, it ->
lists[ 0 ] << ( it.scheduledInMyLearnStatus == 'No' ? 1 :
it.scheduledInMyLearnStatus == 'Yes' ? 2 : 3 )
lists[ 1 ] << ( it.publishedOnTrainingClassesStatus == 'No' ? 1 :
it.publishedOnTrainingClassesStatus == 'Yes' ? 2 : 3 )
lists
}

Answer 3

def myMethod(param, arrayToAdd) {
if(param == "No"){
arrayToAdd.add(1)
}else if(param == "Yes"){
arrayToAdd.add(2)
}else{
arrayToAdd.add(3)
}
}
s2PublicLifecycleInstance.each {myMethod(it.scheduledInMyLearnStatus, scheduledStatusArray)}
s2PublicLifecycleInstance.each {myMethod(it.publishedOnTrainingClassesStatus, publishedStatusArray)}

Answer 4

I agree with gasan. I can add, that
def publishedStatusArray = functionCall(s2PublicLifecycleInstance, propertyName)
is possible in groovy. The function:
functionCall(def s2PublicLifecycleInstance, String propertyName){
s2PublicLifecycleInstance."$propertyName"
}
will return the property you want.