I have sheet 1 that has values from 1 to 100 in column A. For each value there is another corresponding value (random numbers) in column B.
In sheet 2 in column A, I have some of the values from column An in sheet 1, and some that are not present there. I want in column B in sheet 2 to copy the values from column B in sheet 1 where the values in column An in the two sheets match.
Example:
sheet1: A1= 5, B1=4,50
sheet2: for all cells in column A, where it equals 5, set the value in B to 4,50
Put this formula in sheet2!B1
=VLOOKUP(A1,Sheet1!$A:$B,2,0)
and copy down as far as needed.
After this has calculated you can copy pastespecial values if you want to replace the formulas with values
use VLookup. you can find the tutorial here http://www.techonthenet.com/excel/formulas/vlookup.php
Related
I am looking for a formula -
Compare column A sheet 1 and compare column B sheet 2 and if duplicate found, copy and return value on column B sheet 1 from column C sheet 2?
Hope that make sense.
Thanks is advance.
A Classic INDEX/MATCH
In e.g. cell B2 of Sheet1 use:
=IFERROR(INDEX(Sheet2!$C:$C,MATCH($A2,Sheet2!$B:$B,0)),"")
and copy down.
It is actually the same as the inferior:
=IFERROR(VLOOKUP($A2,Sheet2!$B:$C,2,FALSE),"")
Possibly you want to restrict it to something like
=IFERROR(INDEX(Sheet2!$C$2:$C$101,MATCH($A2,Sheet2!$B$2:$B$101,0)),"")
I would like to match the values of Column B and D in Sheet 2 , compare Column D & Column E and return the value of Column E in Sheet1-Column B. I used the formulas below and it is not working. The problem is most of Column A values in Sheet 1 and Sheet 2 are different. So I need to match both Column A. I will enter this formula in Sheet 1 Column B.
How can i change the formula? Help me
=INDEX(Sheet2!$E:$E; AND(MATCH(Sheet1!$A2; Sheet2!$A:$A; 0);MATCH(Sheet2!$B2; Sheet2!$D:$D; 0)))
=INDEX(Sheet2!$E:$E; MATCH(Sheet2!$B2; Sheet2!$D:$D; 0))
In B2 of sheet1 you could put the following:
=VLOOKUP(VLOOKUP(A2,Sheet2!A:B,2,FALSE),Sheet2!D:E,2,FALSE)
The inner lookup =VLOOKUP(A2,Sheet2!A:B,2,FALSE) returns the code e.g. A
and then the outer lookup =VLOOKUP(innerlookupvalue,Sheet2!D:E,2,FALSE), uses this value to do a lookup against the range containing the content values.
You can drag this down for as many rows as you have values. You will need to decide how to handle values that are not found.
What may be a problem is when you say "The problem is most of Column A values in Sheet 1 and Sheet 2 are different", you will get #N/A returned as you can't lookup a non-match. As i said above, you would need to determine how to handle this.
So I have a list of domains in Column D on Sheet 3. If they match a value in column C of Sheet one. I want it to pull the same data thats in column A of sheet 1 and put that the relevant column on sheet 3
In E1 on Sheet3:
=IFERROR(INDEX(Sheet1!A:A,MATCH(Sheet3!D1,Sheet1!C:C,0)),"")
This is assuming you have Excel 2007 or later. Otherwise it needs to be tweaked slightly.
Bit stuck on a problem in Excel. I need to match two columns from Sheet 1 to two columns from Sheet 2, if the results match I need to then return column D's(Sheet2) value into Sheet1. I would of done this manually but this spreadsheet is huge and the reference table (sheet2) will be updated continuously.
My Spreadsheet:
Sheet1: Column G and H
Sheet2: Column B and C
I need to return the value in Column D (Sheet2) into Column A (Sheet1).
Any help on this would be excellent!
Regards,
Neil
There is a column in one of my sheet with 30 locations each location having 12 codes Ex
LOC CODE
1 A
1 B
1 C
1 D
2 A
2 B
2 C
2 D
There is another sheet with only one column
CODE
A
B
C
D
I want to find out whether the all codes in 2nd column of first sheet are present in second sheet. Also I want to know whether all the codes in sheet 2 are present in sheet 1 or not. How can I do that in excel?
Let your codes be in Sheet1 in column B, and in Sheet2 in range A1:A10, then:
1)
I want to find out whether the all codes in 2nd column of first sheet are present in second sheet.
=SUM(IF(Sheet1!B:B<>"",ISNA(MATCH(Sheet1!B:B,Sheet2!A1:A10,0))*1))=0
2)
Also I want to know whether all the codes in sheet 2 are present in sheet 1
=SUM(IF(Sheet2!A1:A10<>"",ISNA(MATCH(Sheet2!A1:A10,Sheet1!B:B,0))*1))=0
Both formulas returns TRUE/FALSE
NOTE, since it's array formulas you should evaluate them by pressing CTRL+SHIFT+ENTER
If you want to know not just that all are present but which, if any, are not then a formula such as:
=IF(MATCH(B2,Sheet1!B:B,0)>0,"present")
in C2 and copied down may suit, assuming your codes are in ColumnB in each sheet and that Sheet1 is adjusted to suit. Where not present the result would show #N/A.