Xml goes blank, when updated with Groovy XmlParser - groovy

Question

I am quite new to groovy and seek your help.
I want to read an delta xml file and update master xml file based on a name attribute. Both the xml files are of same structure. I am trying to update attribute values in the master xml file. But the master file goes blank once, the file is updated. I am not sure where I am wrong.
Below is the xml structure:
<item-descriptor name="user" cache-mode="simple" item-cache-size="3000" query-cache-size="1000" item-cache-timeout="900000" query-expire-timeout="60000" />
<item-descriptor name="contactInfo" cache-mode="simple" item-cache-size="10000" query-cache-size="1000" item-cache-timeout="900000" query-expire-timeout="60000" />
Below is the code for this:
def templatexmlConfig = new XmlParser().parse(templateConfigFile)
def basexmlConfig = new XmlSlurper().parse(baseConfigFile)
def templateItemDesNode = templatexmlConfig.'item-descriptor'
def baseItemDesNode=basexmlConfig.'item-descriptor'
templateItemDesNode.each()
{
Map bindings=[:]
def nameAttr=it.attribute('name')
it.attributes().each{attrName,attrValue->
if(!attrName.equals('name'))
{
bindings.put(attrName,attrValue)
}}
if(baseItemDesNode.find{ it.#name.text().equals(nameAttr)}.size()!=0)
{
bindings.each
{
def a=it.key
def v=it.value
baseItemDesNode.find{ it.#name.text().equals(nameAttr)}.#'a'="${v}" }
}
}
new XmlNodePrinter(new PrintWriter(outputFile)).print(basexmlConfig)

Answer 1

Ok, given two example xml documents:
def templateXml = '''<xml>
| <item-descriptor name="a" cache-mode="r1" item-cache-size="1"/>
| <item-descriptor name="b" cache-mode="r2" item-cache-size="2" new-attr="tim"/>
| <item-descriptor name="z" cache-mode="r3" item-cache-size="3"/>
|</xml>'''.stripMargin() ;
def baseXml = '''<xml>
| <item-descriptor name="b" cache-mode="o1" item-cache-size="10"/>
| <item-descriptor name="c" cache-mode="o2" item-cache-size="11"/>
| <item-descriptor name="a" cache-mode="o3" item-cache-size="12"/>
|</xml>'''.stripMargin()
We can parse these (Using XmlParser for both, you had parser for one, and slurper for the other):
def templatexmlConfig = new XmlParser().parseText( templateXml )
def basexmlConfig = new XmlParser().parseText( baseXml )
And then get the item-descriptor nodes (as you had it)
def templateItemDesNode = templatexmlConfig.'item-descriptor'
def baseItemDesNode = basexmlConfig.'item-descriptor'
Then, loop through the template item-descriptors, generate a map of non-name attributes (using findAll is easier than the loop you had), and replace all nodes on the node in baseXml with the same name:
templateItemDesNode.each() { tidn ->
Map bindings = tidn.attributes().findAll { it.key != 'name' }
def nameAttr = tidn.#name
baseItemDesNode.find { b -> b.#name == nameAttr }?.with { node ->
bindings.each { a, v ->
node.#"$a" = v
}
}
}
And for this easily runnable example, just print out the Xml:
println new StringWriter().with { sw ->
new XmlNodePrinter( new PrintWriter( sw ) ).print(basexmlConfig)
sw.toString()
}
And when run, the above prints out:
<xml>
<item-descriptor name="b" cache-mode="r2" item-cache-size="2" new-attr="tim"/>
<item-descriptor name="c" cache-mode="o2" item-cache-size="11"/>
<item-descriptor name="a" cache-mode="r1" item-cache-size="1"/>
</xml>
Obviously for your working code, you would need to go back to using parse on the XmlParsers to parse your files rather than the Strings I have here, and change the output back to writing to a file...
Hope it helps!