Flat file population of - excel

Question

I import a massive amount of data from SharePoint as a new worksheet (“The Pull”) on an existing book that has four other sections.  I am trying to develop a macro that will, when run, a.) automatically filter the data by a field in the Pull; b.) copy/”paste values” of that filtered data into an existing sheet starting at cell A5; c.) reset the filter on the Pull for the next sheet. 
So for example, in the Pull (default worksheet name “owssvr”), each row has a date in Column AR showing when the item in that row was created.  How do I automatically filter for all items from the previous month in the pull (or alternatively, give the user the option to choose the month), and copy/paste values of the filtered result into a worksheet called “Monthly Report” starting at cell A5 (allowing for the header to not change)?  Is this possible?

Answer 1

This is how I would write that:
Option Explicit
Sub MonthFilter()
Dim LR As Long, MyDate As Date, d1 As Date, d2 As Date
MyDate = Application.InputBox("Enter any date in the month you wish to pull", "Enter Date", Date - 30, Type:=2)
If MyDate = 0 Then
Exit Sub
Else
d1 = DateSerial(Year(MyDate), Month(MyDate), 1)
d2 = DateSerial(Year(MyDate), Month(MyDate) + 1, 1) - 1
End If
With Sheets("The Pull")
.AutoFilterMode = False
.Rows(1).AutoFilter
.Rows(1).AutoFilter 44, Criteria1:=">=" & d1, _
Operator:=xlAnd, Criteria2:="<=" & d2
LR = .Cells(.Rows.Count, 44).End(xlUp).Row
If LR > 1 Then .Range("A2:A" & LR).EntireRow.Copy Sheets("Monthly Report").Range("A5")
.AutoFilterMode = False
End With
End Sub

Answer 2

You can use AutoFilter and ShowAllData to filter and unfilter. Here is an example.
Sub CopyLastMonthFromThePull(shtCopyTo As Worksheet)
Dim rngPullTable As Range, iColumnToFilter As Integer, strMonth As String
' this assumes that the pull data is the first Excel Table on ThePull worksheet named owssvr
Set rngPullTable = ThisWorkbook.Worksheets("owssvr").ListObjects(1).Range
rngPullTable.Parent.Activate
' determine the filter details
strMonth = CStr(DateSerial(Year(Date), Month(Date) - 1, Day(Date))) ' one month prior to today
iColumnToFilter = 44 ' Column AR is the 44th column
' filter the table
rngPullTable.AutoFilter Field:=iColumnToFilter, Operator:=xlFilterValues _
, Criteria2:=Array(1, strMonth)
DoEvents
' copy the filtered results. (This also copies the header row.)
rngPullTable.Copy
With shtCopyTo
.Activate
.Range("A5").PasteSpecial xlPasteFormulasAndNumberFormats
.Columns.AutoFit
.Range("A1").Select
End With
Application.CutCopyMode = False
' remove filter
With rngPullTable.Parent
.Activate
.ShowAllData
End With
rngPullTable.Range("A1").Select
' End with the sheet being copied to active
shtCopyTo.Activate
End Sub