How do I trap new row adds in a list? - excel

Question

I want to execute an VBA event handler in an Excel 10 worksheet whenever the user adds a new row into a list (the kind of lists that Worksheet.ListObjects() returns instances of) on that worksheet, for example by entering data under the last row of the list (this expands the list by adding a new row to the list).
How do I do that? Among other things, I want to set defaults for specific cells of the new row.
My current idea is to handle Worksheet_Change, and check if the Target parameter is within the .Range of the ListObject I am interested in.
However, how would I find out if the user is creating a new row with his/her cell change, and differentiate that from edits of existing cells in the list?
I probably am just a little bit stupid here. I´d expect there would be a list event I could trap, but I cannot find any.

Answer 1

I think you are right, there are no Events for ListObject's. Using Worksheet_Change seems the right way to go. To detect New Row vs Existing Row edit you will need to roll you own method.
I would suggest tracking the number of rows in the ListOjects in order to detect when they change. In order to do this, try adding a hidden named range for each ListOject to hold the current number of rows. Populate them on file open, and test them on Worksheet_Change.
This will add or update hidden named ranges on file open (add to Workbook module)
Private Sub Workbook_Open()
Dim oList As ListObject
Dim sh As Worksheet
Dim nm As Name
Dim strName As String
For Each sh In Me.Worksheets
For Each oList In sh.ListObjects
'oList.ListRows.Count
strName = oList.Name & "Rows"
Set nm = Nothing
On Error Resume Next
Set nm = Me.Names(strName)
On Error GoTo 0
If nm Is Nothing Then
Set nm = Me.Names.Add(strName, CStr(oList.ListRows.Count))
Else
nm.RefersTo = CStr(oList.ListRows.Count)
End If
nm.Visible = False
Next oList, sh
End Sub
This will detect what type of change was made. I've made it a WorkBook level event, so only one is needed for all sheets. (add to Workbook module)
Private Sub Workbook_SheetChange(ByVal sh As Object, ByVal Target As Range)
Dim oList As ListObject
Dim nm As Name
Dim strName As String
For Each oList In sh.ListObjects
strName = oList.Name & "Rows"
If Not Application.Intersect(Target, oList.DataBodyRange) Is Nothing Then
Set nm = Nothing
On Error Resume Next
Set nm = Me.Names(strName)
On Error GoTo 0
If nm Is Nothing Then
Set nm = Me.Names.Add(strName, CStr(oList.ListRows.Count))
nm.Visible = False
End If
If oList.ListRows.Count <> Val(Replace(nm.Value, "=", "")) Then
nm.RefersTo = CStr(oList.ListRows.Count)
MsgBox "List " & oList.Name & " changed" & vbCrLf & "New Line"
Else
MsgBox "List " & oList.Name & " changed" & vbCrLf & "Existing Line"
End If
End If
Next
End Sub
Note: this does not handle the case where the name of an existing ListObject is changed. This is left as an exercise for the reader