How to get all monday (date) for the particular year input - linux

Question

with linux command or perl ,
How to get all monday date for 2010
For example:
20100104 -------- this is jan monday 2010
20100111
20100118
20100125
----
---
---
20101206
20101213
20101220
20101227 -------- this is dec monday 2010

Answer 1

You could use DateTime:
#!/usr/bin/env perl
use strict;
use warnings;
use DateTime;
my $year = 2010;
my $dt = DateTime->new(
'year' => $year,
'month' => 1,
'day' => 1,
);
# find first Monday
while ( $dt->day_name() ne 'Monday' ) {
$dt->add( 'days' => 1 );
}
while ( $dt->year() == $year ) {
print $dt->strftime("%Y%m%d\n");
$dt->add( 'weeks' => 1 );
}

Answer 2

I'd probably do this with DateTime in a very similar manner to Alan's solution. But it's interesting to see how you could also do it using Perl's built-in date-handling facilities.
#!/usr/bin/perl
use strict;
use warnings;
use POSIX 'strftime';
use Time::Local;
my $ONE_DAY = 24 * 60 * 60;
my $ONE_WEEK = 7 * $ONE_DAY;
my $year = shift || 2010;
# Get Jan 1st
my $date = timelocal 0, 0, 0, 1, 0, $year - 1900;
# Get first monday
until (strftime('%a', localtime $date) eq 'Mon') {
$date += $ONE_DAY;
}
while (strftime('%Y', localtime $date) == $year) {
print strftime('%Y%m%d', localtime $date), "\n";
$date += $ONE_WEEK;
}

Answer 3

If you're doing this in Perl, then give Date::Calc a look. I'm a huge fan of Date::Calc, as its large library of functions make these kinds of calculations relatively trivial. For the problem in this question, you could do it with:
use Date::Calc qw(Weeks_in_Year Monday_of_Week);
$wks_in_2010 = Weeks_in_Year(2010);
for ($i = 1; $i <= $wks_in_2010; $i++) {
($mon_year, $mon_month, $mon_day) = Monday_of_Week($i, 2010);
print "$mon_month/$mon_day/$mon_year\n";
}
Remember, Tim Toady.