I have sets of values in rows in Excel
First row contains weights of how much each value in each column contributes to weighted total.
Now, I want to mark in each following row the value that contributed to the weighted total the most, by changing its background. I played with conditional formatting, but my Excel skills are modest, to say the least.
So, how do I do that?
Assuming the weights are in A1:C1 and the values are in A2:C2, enter
=MAX($A$1:$C$1*$A2:$C2)/A$1 as the 'equals' condition for A2
alt text http://www.vulomedia.com/images/12339ExcelConditionalFormatting.jpg
In words this formula is (maximum of (values x weights)) / this column's weight.
Experienced Excel users may notice that if this formula was entered in a worksheet cell it would have to be entered as an array formula to give the correct value. The trick here is that when formulae are used in conditional formats they are always treated as array formulae; no Ctrl-Shift-Enter required.
Here's what I think you are trying to do: You have a list of numbers (they happen to be weights, but that's not important). You want the largest number to be highlighted differently.
Suppose the cells are in the range A1:A8.
Select the range A1:A8.
Select Conditional Formatting (Format | Conditional Formatting)
Enter the condition Cell Value is/Equal To/=MAX(A1:A8)
Click the Format... button and set the Pattern to affect the background.
(Tested on Excel 2003 on Windows.)
Related
Long story short: My boss has an Excel spreadsheet for calculating product prices. She has three columns to calculate different margins (so would contain a formula like =cost*.5 etc.), then adds to those values to determine final retail (so would be =column+500). She has her margin columns highlighted different colors and wanted to automatically highlight the final retail cell based on which margin column it references.
I'm sure there's a way of setting up the document from the start that makes this more intuitive, but short of restructuring her entire system, are there any formulas I could use in combination to return a format based on the content of the formula?
I immediately assumed to use "if cell contains specific text" and use the referenced column letter as the text, but excel reads the output for the formatting and not the formula, so I am stumped.
I was thinking somehow to use "isformula", but all the values are formulas just with different input.
Suppose you made table of all the unique formulas that are used:
formula_test, rule,
=cost*0.5,1
=column+500,2
Then you could create conditional formatting rules by formula with one for each unique formula case.
=VLOOKUP(FORMULATEXT(A1),$A$2:$B$3,2,FALSE)=1
=VLOOKUP(FORMULATEXT(A1),$A$2:$B$3,2,FALSE)=2
Where A1 is the first cell in the range where you want the conditional formatting to be applied.
The missing link was "SEARCH":
=SEARCH("=Sum(J",FORMULATEXT(N2))
(J = the referenced margin column, N2 = first cell to apply the final retail formula)
What is the best formula to get the average if Criteria is Vertical and Range is Horizontal? I have multiple sheets and workbooks that needs to be averaged based on its criteria and doing manually is not the best way.
I tried using =AVERAGE(IF($E$1:$Q$1=A2,E2:Q15)) however blank cell are being considered with 0 value and affects the actual average. blank cell should not be calculated on as zero on average.
Edit: Added tried/not working formula.
The formula below will work for cell A2 (and can then be copied down)
=SUM(INDEX($E$2:$Q$15,,MATCH(A2,$E$1:$Q$1,0))/COUNTIF(INDEX($E$2:$Q$15,,MATCH(A2,$E$1:$Q$1,0)),">0"))
if you don't have dynamic arrays then it must be entered as an array formula with Ctrl+Shift+Enter
(if you have Excel 365 then the formula can be shortened
=LET(data,INDEX($E$2:$Q$15,,MATCH(A2,$E$1:$Q$1,0)),SUM(data)/COUNTIF(data,">0"))
)
I am currently trying to apply conditional formatting to certain rows which contain numbers in percentage (e.g. F11 to N11; F14 to N14; F17 to N17 and so on). These are also the only rows in the worksheet that have numbers in percentage. Would like to know what the fastest way to go about doing this is.
Should I:
(i) apply conditional formatting to the whole worksheet to numbers in percentage (if possible) or
(ii) apply conditional formatting to each individual row which is extremely time-consuming?
Appreciate if anyone can help.
Thanks in advance! :)
If your data in the percentage rows is also formatted as percentage, you can use the =CELL("format",[reference]) function, that returns "P0" or "P2" for percentage formatting.
Use a helper column (which you can hide if you want) to check the formatting of the first/last cell in the row, and then set conditional formatting based on the column:
After you create the column, you set a conditional formatting rule on the the upper-left cell in the range based on the formula: =[top cell in helper column]="P0". Keep the column fixed with a $ but not the row, as in the screenshot below, so you can drag the formatting to all the range with correct reference to the helper column.
Next step is to drag this cell to all the range, choosing the "formatting only" option:
Finally, you have to format again all rows that contains percentage values to percentage formatting.
However, if the place of the percentage rows is fixed, you don't need that CELL() function, just write in the helper column something like p or 1 for the rows to format.
(I have also tried to plug the formula directly to the formatting condition, but it doesn't work well all the time)
Tell me if it solved your problem ;)
I have several columns where the data from rows 7 onwards changes depending on the selection made from a dropdown menu in row 6. Most of these options will result in textual or number based values appearing, but two of them would need to be formatted as currency.
Essentially what I want is a conditional formatting formula that says; if row six in any column has a value of “Implied Unit Rate” or “Annual budget”, format rows 7 and onwards in that column as currency.
I can get this to work by creating two separate conditional formatting formulas and applying them both to the whole area, but it seems like there should be a way to do it in a single formula.
My current formulas, applied as two separate rules:
=INDIRECT(ADDRESS(6,COLUMN(),1))="Annual Budget"
=INDIRECT(ADDRESS(6,COLUMN(),1))="Implied Unit Rate"
How I think it should work when applied as one rule:
=OR(INDIRECT(ADDRESS(6,COLUMN(),1))="Annual Budget",
INDIRECT(ADDRESS(6,COLUMN(),1))="Implied Unit Rate")
When I enter the combined formula in a regular cell within the worksheet, it does return true as expected, but does nothing when I apply it as a conditional formatting rule. Any ideas? Thanks in advance!
Now I may be mis interpreting what Scott is saying, so I am going to say this in my own words.
Your condition check on the cell address in question is a little "verbose". In order to apply your conditional formatting, select the range you want to apply your condition formatting to first. Lets arbitrarily say select range A7 to D42. After selecting the appropriate range, ensure cell A7 is the active cell of the selected range. This usually means there is a border around A7 to D42 and all cells but A7 have been slightly greyed to indicate that they have been selected, and A7 will have a brighter background to indicate that it is the active cell. With all that still in effect, select your conditional formatting.
In conditional formatting choose formula as the option (last one at the bottom) to control how your formatting will be applied. In the region where you can enter your formula, enter the following:
=OR(A$6="Annual Budget", A$6="Implied Unit Rate")
The $ will keep the row and column reference from changing as it is applied to each cell in the range. It will always be checking row 6 of what ever column the cell is in. The column A reference is relative to the active cell.
I'm trying to apply conditional formatting in Excel on a range of cells, based on the adjacent cell's value, to achieve something like this:
The goal is to highlight values in Column B (Actual Expense) red if the value is greater than it's adjacent value in column C (Expected Expense). I've followed a number of tutorials that said to apply conditional formatting by selecting Conditional Formatting>New Rules>Use a Formula to Determine Which Cells to Format then applying a rule =$B4>$C4 which would format the 'Actual' cell red if it were greater than the 'Expected' cell. This works great for one cell, but not so well when I attempt to apply this to a range of cells. I've used the format painter as well as editing the rule to be applied over a range of cells (i.e. $B$2:$B$5) as shown below but it only bases the formatting on the initial formula (if B4 is greater than C4) and everything undesirably turns red.
I'd rather not make individual rules for every row. Is there a way to consolidate this into one rule?
You need to take out the $ signs before the row numbers in the formula....and the row number used in the formula should correspond to the first row of data, so if you are applying this to the ("applies to") range $B$2:$B$5 it must be this formula
=$B2>$C2
by using that "relative" version rather than your "absolute" one Excel (implicitly) adjusts the formula for each row in the range, as if you were copying the formula down
I don't know if maybe it's a difference in Excel version but this question is 6 years old and the accepted answer didn't help me so this is what I figured out:
Under Conditional Formatting > Manage Rules:
Make a new rule with "Use a formula to determine which cells to format"
Make your rule, but put a dollar sign only in front of the letter: $A2<$B2
Under "Applies to", Manually select the second column (It would not work for me if I changed the value in the box, it just kept snapping back to what was already there), so it looks like $B$2:$B$100 (assuming you have 100 rows)
This worked for me in Excel 2016.