Excel Lookup Return Unique Value - excel

Question

I have two sheets one has
Item ID
Box 78
Glue 105
Box 85
The other sheet
Item ID
Box
Box
Glue
On the second sheet I want to look up the an ID from the first sheet.
Where there I duplicates (as in Box) I want to return the IDs one at a time.
So the lookup on Box would return 78 the first time, and 85 the second time.
Like this:
Item ID
Box 78
Box 85
Glue 105

Answer 1

Alternate solution. Does not require helper columns, does not require array entry. In Sheet2 cell B2 and copy down:
=INDEX(Sheet1!$B$2:$B$4,MATCH(1,INDEX((Sheet1!$A$2:$A$4=A2)*(COUNTIF(B$1:B1,Sheet1!$B$2:$B$4)=0),),0))

Answer 2

You can use a slight variation of INDEX/MATCH:
=INDEX(B$2:B$4,SMALL(IF(A$2:A$4=C2,ROW(B$2:B$4)-1,""),COUNTIF(C$2:C2,C2)))
Confirm as an array formula with Ctrl+Shift+Enter, then autofill down.
Explanation of cell references:
A$2:A$4 - Item Column (sheet1)
B$2:B$4 - ID Column (sheet1)
C$2:C2 - Item Column (sheet2)
C2 - The item you're looking up

Answer 3

At first glance this seems impossible, because VLOOKUP doesn't know how to deal with multiple Boxes.
But using this ingenious answer you actually CAN make this work.
On Sheet 1, enter the formulae:
Which results in:
item instance combined id range_above
Box 1 Box1 78 $A$2:$A$2
Glue 1 Glue1 105 $A$2:$A$3
Box 2 Box2 85 $A$2:$A$4
You can now VLOOKUP off combined instead of off item. (Obviously you'll have to do an identical trick in sheet 2.)
Note this all these formulae can just be extended down however long your table is. It will always just work.

Answer 4

A good method for doing this would be to use an array formula to look up the values from the first sheet using the number of repetitions of each item from the second sheet. This method requires no "helper" columns.
The formula that will accomplish this is: {=INDEX(Sheet1!A:B,SMALL(IF((Sheet1!A:A)=Sheet2!A2,ROW(Sheet1!A:A),""),COUNTIF($A$2:$A2,"="&$A2)),2)}
This formula is an array formula. You can copy it into cell B2 on Sheet2, and press Ctrl+Shift+Enter to enter it. You must press Ctrl+Shift+Enter to make this an array formula. You can drag this formula down column B for as many rows as you would like.
Your worksheet, when finished, will contain the following formulas:
Let's break this formula down into its components:
Identify how many times a given item has been repeated in column A. We accomplish this with the following code, which will count the number of times that the current row's item has appeared in all previous rows in column A. The absolute reference for the start of the range and the relative reference for the end ensures that the range will be automatically updated as we drag the formula down in column B:
COUNTIF($A$2:$A2,"="&$A2)
Identify the kth row in Sheet1 containing the item in column A of Sheet2. The following code first uses an IF statement to find all rows in Sheet1 containing the item in Column A of Sheet2. This uses array syntax to compare all rows in the specified range against a value. The IF statement returns an array containing the rows that were identified if any were found. If none were found, it returns the empty string.
IF((Sheet1!A:A)=Sheet2!A2,ROW(Sheet1!A:A),"")
Look up the value of the nth row that was identified using the SMALL function, which selects the nth smallest item from an array. For k, we pass the count that was calculated in step 1.
SMALL(IF((Sheet1!A:A)=Sheet2!A2,ROW(Sheet1!A:A),""),COUNTIF($A$2:$A2,"="&$A2))
Finally, we put it all together in the INDEX function, which will look up the value at the specified row (identified in step 3) and column (2), in a given range.
{=INDEX(Sheet1!A:B,SMALL(IF((Sheet1!A:A)=Sheet2!A2,ROW(Sheet1!A:A),""),COUNTIF($A$2:$A2,"="&$A2)),2)}