How do you write a function that can utilize sumif across an array? - excel-formula

Question

Is there a way to write a single function to do the following in excel/sheets?
Sum measure_a and measure_b by date
Filter by employee and the new sum_measure_a >= 30
Calculate the mean for all of the new sum_measure_b
Here is an example...
employee
date
measure_a
measure_b
AA
2/1
10
50
AA
2/1
10
50
AA
2/1
20
80
AA
2/2
10
40
AA
2/2
10
50
AA
2/3
20
80
AA
2/3
20
90
BB
2/1
30
100
[![enter image description here][1]][1]
So the expected output would be a function that
Would filter all employee values by lookup (here AA)
Would calculate the sum of measure_a for each date
Would identify 2/1 and 2/3 as the dates required (based on the sum of measure_a >= 30)
Would sum the total for each measure_b for each of those day (here 2/1 = 180 and 2/3 = 170)
And finally finds the mean for the daily totals. So final answer is 175 for AA.
employee
mean_measure_b
AA
175
BB
100

Answer 1

you can try:
=QUERY(QUERY({A2:D},"Select Col1, Col2, SUM(Col3), SUM(Col4) WHERE Col1<>'' GROUP BY Col1, Col2"),"Select Col1, AVG(Col4) Where Col3>=30 GROUP BY Col1 LABEL AVG(Col4)'' ")

Answer 2

In Excel this could be done using Microsoft 365:
=LET(data, A2:D9,
empl, INDEX(data,,1),
date, INDEX(data,,2),
m_A, INDEX(data,,3),
m_B, INDEX(data,,4),
e_d, HSTACK(empl,date),
u, UNIQUE(e_d),
u_1, INDEX(u,,1),
u_2, INDEX(u,,2),
mm_cond,(TRANSPOSE(empl)=u_1)*(TRANSPOSE(date)=u_2),
mm_A, MMULT(mm_cond,m_A),
mm_B, MMULT(mm_cond,m_B),
filtered, FILTER(HSTACK(u_1,mm_B),mm_A>=30),
Unq, UNIQUE(INDEX(filtered,,1)),
mm_cond_B,--(TRANSPOSE(INDEX(filtered,,1))=Unq),
sum_B, MMULT(mm_cond_B,INDEX(filtered,,2)),
count_B MMULT(mm_cond_B,SEQUENCE(COUNTA(INDEX(filtered,,2)),,1,0)),
HSTACK(Unq,sum_B/count_B))
It first calculates the sum of measure a for each unique employee/date combination and the same for measure b.
Then it filters out the lines where the sum of measure a is smaller than 30.
Than it takes the average of the listed values for each employee.