How to prevent email from sending without attachment - excel

Question

I put in the on error resume next to continue if it cant find an email but now if it cant find an attachment it'll still send where as I need it to not send without an attachment and still continue if no email
Sub CreateStatement()
Dim EApp As Object
Set EApp = CreateObject("Outlook.Application")
Dim EItem As Object
'Dim EApp As Outlook.Application
'Set EApp = New Outlook.Application
'Dim EItem As Outlook.MailItem
'Set EItem = EApp.CreateItem(olMailItem)
Dim path As String
path = "K:\E-Fax Invoicing\PDF Output\"
Dim RList As Range
Set RList = Range("A2", Range("a2").End(xlDown))
Dim R As Range
For Each R In RList
Set EItem = EApp.CreateItem(0)
With EItem
On Error Resume Next
.SentOnBehalfOfName = ""
.To = R.Offset(0, 2)
.Subject = "December Statement: "
.Attachments.Add (path & R.Offset(0, 3))
.Body = "Dear " & R & vbNewLine & vbNewLine _
& "Please find your " & R.Offset(0, 4) & " attached."
On Error GoTo 0
If .Attachments.Count > 0 Then
.send
Else
next
End If
End With
Next R
Set EApp = Nothing
Set EItem = Nothing
End Sub

Answer 1

You can check to see if the file exists before trying to add it as an attachment:
Sub CreateStatement()
Const PATH = "K:\E-Fax Invoicing\PDF Output\" 'use const for fixed values
Dim EApp As Object, EItem As Object, RList As Range, R As Range
Set EApp = CreateObject("Outlook.Application")
Set RList = Range("A2", Range("a2").End(xlDown))
For Each R In RList.Cells
f = Dir(PATH & R.Offset(0, 3).Value) 'any matching file?
Set EItem = EApp.CreateItem(0)
With EItem
.SentOnBehalfOfName = ""
.To = R.Offset(0, 2)
.Subject = "December Statement:"
.Body = "Dear " & R.Value & vbNewLine & vbNewLine _
& "Please find your " & R.Offset(0, 4).Value & " attached."
If Len(f) > 0 Then
.Attachments.Add PATH & f
.send
Else
.display
End If
End With
Next R
End Sub