Ambiguous Userform name - excel

Question

I create Userform
'Sub Crt_UserForm(ByVal count23 As Long, ByVal Temp As String, shts As Variant)
Dim myForm As Object
Dim Textbox1 As MSForms.TextBox
Dim Textbox2 As MSForms.TextBox
Dim Label1 As MSForms.Label
Dim Label2 As MSForms.Label
Dim Button1 As MSForms.CommandButton
Dim Button2 As MSForms.CommandButton
'Dim shtchk() As MSForms.CheckBox
Set myForm = ThisWorkbook.VBProject.VBComponents.Add(3)
'Set myForm = CallByName(UserForms, "Add", VbMethod, "Test")
ReDim shtchk(count23) As MSForms.CheckBox
With myForm
.Properties("Name") = "Test" 'Иногда эта строка вызывает ошибку
.Properties("Caption") = "Выберите листы для защиты паролем"
.Properties("Width") = 300
.Properties("Height") = 150
End With
'For Each x In Me.UserForms
'If x.Name = "Test" & a Then
'Next x
Set Label1 = Test.Controls.Add("Forms.Label.1", "Label1")
Set Label2 = Test.Controls.Add("Forms.Label.1", "Label2")
Set Textbox1 = Test.Controls.Add("Forms.Textbox.1", "Textbox1")
Set Textbox2 = Test.Controls.Add("Forms.Textbox.1", "Textbox2")
Set Button1 = Test.Controls.Add("Forms.CommandButton.1", "Button1")
Set Button2 = Test.Controls.Add("Forms.CommandButton.1", "Button2")
With Label1
.Top = 10
.Left = 10
.Width = 50
.Height = 20
.Caption = "Текущий пароль"
End With
With Label2
.Top = 10
.Left = 70
.Width = 50
.Height = 20
.Caption = "Новый пароль"
End With
With Textbox1
.Top = 40
.Left = 10
.Width = 50
.Height = 20
'.Caption = "Новый пароль"
End With
With Textbox2
.Top = 40
.Left = 70
.Width = 50
.Height = 20
'.Caption = "Новый пароль"
End With
With Button1
.Top = 70
.Left = 10
.Width = 50
.Height = 20
'.Caption = "Новый пароль"
End With
With Button2
.Top = 70
.Left = 70
.Width = 50
.Height = 20
'.Caption = "Новый пароль"
End With
Test.Show
End Sub
'
after the actions are over, I delete the created userform:
Sub RemoveUserForm()
With ThisWorkbook.VBProject.VBComponents
.Remove .item("Test")
End With
End Sub
First time it runs OK. But when I run it second time, it gives the error "Ambiguous name detected: Test" in the string:
Set Label1 = Test.Controls.Add("Forms.Label.1", "Label1")
So, somewhere deleted object myForm with the name "Test" is stored and prevents from creating the Userform object with the same name. How to fix it?

Answer 1

The solvation was in method of call to userform object via .Designer property Set Label1 = myForm.Designer.Controls.Add("Forms.Label.1", "Label1")
and method of userform show VBA.UserForms.Add(s).Show
Sub Crt_UserForm()
Dim myForm As Object
Dim s As String
Dim Textbox1 As MSForms.TextBox
Dim Textbox2 As MSForms.TextBox
Dim Label1 As MSForms.Label
Dim Label2 As MSForms.Label
Dim Button1 As MSForms.CommandButton
Dim Button2 As MSForms.CommandButton
Set myForm = ThisWorkbook.VBProject.VBComponents.Add(3)
With myForm
.Properties("Caption") = "Smth"
.Properties("Width") = 300
.Properties("Height") = 150
End With
s = myForm.Name
Set Label1 = myForm.Designer.Controls.Add("Forms.Label.1", "Label1")
Set Label2 = myForm.Designer.Controls.Add("Forms.Label.1", "Label2")
Set Textbox1 = myForm.Designer.Controls.Add("Forms.Textbox.1", "Textbox1")
Set Textbox2 = myForm.Designer.Controls.Add("Forms.Textbox.1", "Textbox2")
Set Button1 = myForm.Designer.Controls.Add("Forms.CommandButton.1", "Button1")
Set Button2 = myForm.Designer.Controls.Add("Forms.CommandButton.1", "Button2")
With Label1
.Top = 10
.Left = 10
.Width = 50
.Height = 20
.Caption = "SMTH"
End With
With Label2
.Top = 10
.Left = 70
.Width = 50
.Height = 20
.Caption = "SMTH"
End With
With Textbox1
.Top = 40
.Left = 10
.Width = 50
.Height = 20
End With
With Textbox2
.Top = 40
.Left = 70
.Width = 50
.Height = 20
'.Caption = "SMTH"
End With
With Button1
.Top = 70
.Left = 10
.Width = 50
.Height = 20
.Caption = "OK"
End With
With Button2
.Top = 70
.Left = 70
.Width = 50
.Height = 20
.Caption = "SMTH"
End With
With myForm.CodeModule
x = .CountOfLines
.InsertLines x + 1, "Sub Button1_Click()"
.InsertLines x + 2, "MsgBox ""Hello!"""
.InsertLines x + 3, "Unload Me"
.InsertLines x + 5, "End Sub"
End With
VBA.UserForms.Add(s).Show
ThisWorkbook.VBProject.VBComponents.Remove VBComponent:=myForm
End Sub