Power Bi - issue with if measure - excel

Really appreciate your help with this ! I am trying to analyze some data in power bi and this is how the data is current displayed ( just an example )
Table look like this :
I am not allowed to post a pic but i hope this understand ( bold is header and the rest is the content )
1)Company 2)No of error 3)No of time to be used
A 1 3
A 4 1
B 1 2
B 1 2
C 0 1
I want the table to change into this :
1)Company 2)No of error 3)No of time to be used
A 0 1
B 0 1
C 1 1
So to explain this : so it sums what is for the same company and if the eroors are >1 then will display 0 otherwise will be 1 . For how many time is used it's the other way , if it's been used once it will 1 otherwise 0.
The purpose for this will be to calculate for a speacific period : No of errors/ no of time used *100. ( so it will count how many 1s have been in that period and do the maths )
I have used an if measure but it doesn't help as i can't count ifs ( not sure if it makes sense )
Thanks a lottt! :)


Hello Please try this code:
You need to create "New Table" command,then paste the code:
Full DAX Code:
NewTable =
ADDCOLUMNS (
VALUES ( YourTable[Company] ),
"Test1", CALCULATE ( IF ( SUM ( YourTable[No of error] ) > 1, 0, 1 ) ),
"Test2", CALCULATE ( IF ( COUNT ( YourTable[Company] ) >= 1, 1, 0 ) )
)
If we test it,


Add company to a table visual and then add the following two measures.
Measure1 = INT( NOT( CONVERT( SUM('Table'[No of error]), BOOLEAN)) )
Measure2 = INT( CONVERT( SUM('Table'[No of time to be used]), BOOLEAN))

Related

MAX Value based on two Numbers and one Text

I have a huge Order-Master-Table that contains the complete manufacturing routing for each order.
Now I would like to determine the last tracked quantity in this table.
The table has a structure like:
Order Nr
Prio 1 (Number)
Prio 2 (Number)
Prio 3 (Text)
Quantity
The measure should look at Prio 1 at first, then at Prio 2, and at last on Prio 3.
Prio and Prio 2 are Numbers between 2 and 99 possible.
In Prio 3 are different Text strings possible, but for the tracked quantity are just "OX" and "OK" necessary. Here has "OX" always more priority than "OK".
How would you build that as a DAX Measure?
MAXX, CALCULATEDTABLE, RANK, TOPN?
This is my first approach:
VAR Max1 =
MAXX (
ALLSELECTED ( 'Order Master' ),
'Order Master'[Prio 1]
)
VAR Max2 =
MAXX (
ALLSELECTED ( 'Order Master' ),
'Order Master'[Prio 2]
)
RETURN
MAXX(
FILTER(
'Order Master',
'Order Master'[Prio 1] = Max1 && 'Order Master'Prio 2] = Max2
),
'Order Master'[Quantity]
)

I would translate "OX" and "OK" into numbers, just like the other priorities. This can be done very simply using an IF-formula:
=IF(A1="OX";0;IF(A1="OK";1;-1))
(Just as an example, obviously)
If, however, by "OX" you mean every possible value for "X", like "O1", "O32", ..., then I'd propose you to write a VBA function for performing the mentioned translation.

How to combine the index function with multiple criteria?

I am having trouble figuring out an index function. My datasheet is as follows
Tab 1 - complete list of all subcompanies held by all holding companies
- The first column shows holding companies
- the second column shows the subcompanies held by each holding company
- the third, fourth and fifth column give the key financials of these subcompanies (EBITDA)
The tabs after Tab 1 are tabs for every holding company. In these tabs I have a section where I want to only include the subcompanies from Tab 1 with an EBITDA higher than 20 million
Example:
Holding company A has the following subcompanies: Sub1 (EBITDA:10m), Sub2 (EBITDA: 21m), Sub3 (EBITDA: 15m).
In the tab of company A I want to only display the information of Sub2 as it meets the minimum threshold
The function I have now displays all information of each subcompany per holding company regardless of their EBITDA:
=IFERROR(INDEX(Tab1!D$5:D$337,SMALL(IF(Tab1!$C$5:$C$337=$C$6,ROW(Tab1!D$5:D$337)-MIN(ROW(Tab1!D$5:D$337))+1),ROWS(B$55:B55))),"")
Tab1 Column D has all the subcompany names
Tab1 Column C has all holding company names
Column B is where I insert the subcompanies in the holding company tab
The output provides all subcompanies per holding, but I only want the subcompanies per holding with an EBITDA equal or larger than 20m
How can I add a criteria to filter if one or more of the 3 years worth of EBITDAs (Tab1 Column N, O & P) per subcompany is equal or larger than 20m?
Many thanks in advance!

Change the criteria in the IF statement from:
Tab1!$C$5:$C$337=$C$6
to also check columns N, O or P being over 20m:
(Tab1!$C$5:$C$337=$C$6)*((Tab1!$N$5:$N$337>20000000)+(Tab1!$O$5:$O$337>20000000)+(Tab1!$P$5:$P$337>20000000))

You are using a FormulaArray, however, you could also use this standard formula (entered at B6):
= IFERROR( INDEX( 'Tab1'!$D$5:$D$337,
AGGREGATE( 15, 6, ROW(B:B) /
( ( 'Tab1'!$C$5:$C$337 = $C$6 ) *
( ( 'Tab1'!$N$5:$N$337 > 20 ) + ( 'Tab1'!$O$5:$O$337 > 20 ) + ( 'Tab1'!$P$5:$P$337 > 20 ) <> 0 ) ),
ROWS( B$5:B5 ) ) ), "" )

In Infopath how to exclude Saturdays and Sundays while calculating the Due Date

In Infopath i have two datepicker, if i select any date from the first date picker, it has to add 15 days and should display in second datepicker excluding saturday and sundays.
I tried using today() and addDays() functions but not works.
If Any idea, please suggest.

You can look for the something as given below but not sure though:(
http://sharepoint-community.net/forum/topics/how-to-calculate-difference-between-dates-excluding-saturdays-and
I created two date pickers in SPD named Issued and completed , and then i added a calculated column .. added the formula below to it , set the data type as text only and it worked ,
= ( [Completed] - [Issued] )
- ( ROUNDDOWN( ( [Completed] - [Issued] ) / 7 , 0 ) * 2 )
- ( IF( WEEKDAY( [Issued] ) = 7 , 1 , 0 ) )
- ( IF( WEEKDAY( [Completed] ) = 1 , 1 , 0 ) )
- 1
It calculated the weekdays only and excluded weekends
Thanks

Formula for finding vacancy percentage by month from check-in and check-out dates

I'm working on one spreadsheet. I want to find out total nights (month wise) from check-in and check-out date, Vacancy % (month wise), and Avg Night rate (month wise).
I've created simple format with google spreadsheet. Please check this https://docs.google.com/spreadsheets/d/1AZfpAic0PT3phLiedZh7I43pu6A3L9w4RhTchKtA0zw/edit#gid=0
In short, need to fill up "??" fields.

Assuming the sample data is located at C6:H63 (adjust as needed)
Note: Included three records at the beginning to show summaries for next year as well as error for monthly occupancy beyond monthly capacity.
This solution requires:
Two Working cells to provide flexibility and space for growth:
Capacity (rooms) : Located at E4; used to hold total numbers of rooms (actually is one, hopefully the business will growth).
Year : Year of the first period in Data, used to update header of “Monthly Allocation”, “Monthly Summary”. Located at K4
Total Nights : Modification of the formula to calculate Total Nights in column E in order to validated Check In & Check Out dates. Enter this formula in E7 and copy till last record:
=ISNUMBER( C7 ) * ISNUMBER( D7 ) * ( $D7 > $C7 ) * SUM( $D7, - $C7 )
The Results Range includes two areas (see Fig. 1)
Monthly Allocation : located at J6:V63
Header : Update Number Format for range J6:X6 as mmm-yy and Y6 as mmm dd, yyyy. Used to update the header of this area. Enter this formula in J6
=DATE( $K$4, 1, 1 )
And this formula in K6 and copy to L6:X6
= 1 + EOMONTH( J6, 0 )
Then enter this formula in Y6
=EOMONTH(X6,0)
Body : To allocate monthly occupancy enter this formula in J7 and copy till last record then copy to other months K7:X63
=IFERROR( IF( $E7 = 0, "", CHOOSE( 1
+ ( 1 + EOMONTH( $C7, -1 ) = J$6 ) * 1
+ AND( 1 + EOMONTH( $C7, -1 ) < J$6, 1 + EOMONTH( $D7, -1 ) > J$6 ) * 2
+ ( 1 + EOMONTH( $D7, -1 ) = J$6 ) * 3,
"",
1 + DAYS( EOMONTH( J$6, 0 ), $C7 ),
1 + DAYS( EOMONTH( J$6, 0 ), J$6 ),
DAYS( $D7, J$6 ),
SUM( $D7, - $C7 ) ) ),
"" )
Monthly Summary : located at I65:Y67
Total Nights : Enter this formula in J67 and copy tillY67`
=SUM( Y$7:Y$63 )
Vacancy % : Enter this formula in J65 and copy till Y65. This formula also validates the total occupancy against total capacity and returns !Err if occupancy > capacity (see Dec-15 in fig. 2).
=IF( J$67 > ( ( 1 + DAYS( EOMONTH( J$6, 0 ), J$6 ) ) * $E$4 ), "!Err",
1 - J$67 / ( ( 1 + DAYS( EOMONTH( J$6, 0 ), J$6 ) ) * $E$4 ) )
Avg Nightly Rate : Enter this formula in J66 and copy till X66
=SUMPRODUCT( J$7:J$63, $H$7:$H$63 )
and enter this formula in Y66
= 1 - $Y$67 / ( ( 1 + DAYS( $Y$6, $J$6 ) ) * $E$4 )
Fig. 1
Fig. 2

You need to allocate the days in each visit to the right month even when the visit is split over two months. I'm going to start by adding 12 helper columns with headers 1-12 (i.e. one per month) in columns I to T and use the following formula starting from I2 to find how many days to put in each month for each visit:-
=MAX(MIN(EOMONTH(DATE(2015,I$1,1),0)+1,$D2)-MAX(DATE(2015,I$1,1),$C2),0)
Then to get the vacancy percentage per month starting in V7 and pulled across:-
=(DAY(EOMONTH(DATE(2015,I$1,1),0))-SUM(I2:I55))*100/DAY(EOMONTH(DATE(2015,I$1,1),0))
To get the average room rate per month starting in V8 and pulled across:-
=ArrayFormula(iferror(SUM(I2:I55*$H2:$H55)/SUM(I2:I55),""))
And to get the total number of nights per month starting in V9 and pulled across:-
=sum(I2:I55)
Helper columns:-
Results:-

Look up formula works well except for one column

I have an excel file that has been uploaded here
http://www58.zippyshare.com/v/99974349/file.html
The formula works great except for a column with descending values.
=INDEX(
INDIRECT("'"&LOOKUP(B5,TblA)&"'!A6:A36"),
LOOKUP(9.99999999999999E+307,
SEARCH("-"&C8&"-","-"&INDIRECT("'"&LOOKUP(B5,TblA)&"'!C6:C36")&"-"),
ROW(C6:C36)-ROW(C6)+1))
Let me explain the excel file.
I have one main sheet 'Report' and 4 other sheets correspond to 4 age groups. - 4.2.0 to 4.7.30, 4.8.0 to 5.1.30, 5.2.0 to 5.7.30 and 5.8.0 to 6.1.30. Depending on the Age (B5) in the sheet 'Report', I select one of the 4 sheet to pick values from. I pick the correct sheet using a Table Name TblA which contains all sheet names and is defined from A24 to B27 in the sheet 'Report'.
In the sample sheet that is uploaded, B5 contains the value 5.7 which means we have to select the sheet 5.2.0 to 5.7.30.
Now from the sheet 5.2.0 to 5.7.30, I have to seek the respective Standard Score (1st column) for every Raw Score entered in 'Report'.
Here are the steps:
A. Enter Raw scores in sheet 'Report' C7 to C15
B. Search Respective sheet depending on age (B5 cell), in our case 5.2.0 to 5.7.30 since age is 5.7
C. Populate Standard score from Raw scores by picking the corresponding column in the 4 sheets. For example, if Raw Score of Col1 is 25 (C7), then pick the Standard score of Col1 from 5.2.0 to 5.7.30 and enter in D7 and so on.
D. This way all standard scores are filled in D7 to D15.
The formula works great except for D13 in sheet 'Report' since if you observe ColD in 5.2.0 to 5.7.30, it is in descending order.
How do I change the formula to accomodate this unique column?

Well, it's not really the order that's causing the error, it's because you don't have any results! The formula you use is trying to find -159- which it cannot find at all in the age sheet. You really need something to look into ranges, so that if you have 159, it will return a positive result when you try to match against 139-160.
I have made a formula building it from smaller ones, but when assembled, the repeating units make it daunting... Also, it's an array formula, so you need to use Ctrl+Shift+Enter for it to work as intended. You can still drag the formula down.
=INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!A6:A36"),
IFERROR(
MATCH(
C7,
INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
)*1,
0
),
MATCH(
1,
IF(
1*LEFT(
INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
),
FIND(
"-",
INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
)
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
),
FIND(
"-",
INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
)
)+1,
100
)>=C7,
1,
0
)
,0
)
)
)
The single line version...
=INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!A6:A36"),IFERROR(MATCH(C7,INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0))*1,0),MATCH(1,IF(1*LEFT(INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)))-1)<=C7,1,0)*IF(1*MID(INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)))+1,100)>=C7,1,0),0)))
You can notice that there are some repeating blocks, namely:
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36")
For the sheet name;
INDEX(
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
)
Which is a larger block to make the formula a bit more flexible (it automatically picks the correct column e.g. if you change B8 Exclusion to Col1, the formula will automatically adjust itself)
If I call the first Sheet and the second Column, it becomes much shorter and perhaps easier to understand:
=INDEX(
Sheet,
IFERROR(
MATCH(
C7,
Column*1,
0
),
MATCH(
1,
IF(
1*LEFT(
Column,
FIND(
"-",
Column
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
Column,
FIND(
"-",
Column
)+1,
100
)>=C7,
1,
0
)
,0
)
)
)
Or
=INDEX(Sheet,IFERROR(MATCH(C7,Column*1,0),MATCH(1,IF(1*LEFT(Column,FIND("-",Column)-1)<=C7,1,0)*IF(1*MID(Column,FIND("-",Column)+1,100)>=C7,1,0),0)))
Disclaimer: I'm not sure if there are any way to make this even shorter, but I guess that as long as it's working right now ^^
You can download your updated sheet here.
Explanation:
As I mentioned before, the formula is based off several smaller ones and quite a few repeats of those.
INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36")
As you already know (it's a variation of a part of your own formula), this gives the area containing all the different ages. Using it and the below, we get this:
INDEX(
INDIRECT('"&LOOKUP($B$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)
)
Into:
INDEX(
'Sheet'!B6:J36,
0,
MATCH(B7,'Sheet'!B5:J5,0)
)
Index will thus look into the range 'Sheet'!B6:J36, 0 indicates it will take any column(s) and MATCH(B7,'Sheet'!B5:J5,0) returns the nth column by taking the value of B7 (in the case of your spreadsheet, Col1) and looking it into 'Sheet'!B5:J5 which gives 1. The above will thus return the range 'Sheet'!B6:B36. Let's put it in the formula:
=INDEX(
'Sheet'!A6:A36,
IFERROR(
MATCH(
C7,
'Sheet'!B6:B36*1,
0
),
MATCH(
1,
IF(
1*LEFT(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)+1,
100
)>=C7,
1,
0
)
,0
)
)
)
This formula is itself a giant INDEX formula, with range 'Sheet'!A6:A36 and row number as the big IFERROR group. The first part of the IFERROR() gets evaluated first:
MATCH(
C7,
'Sheet'!B6:B36*1,
0
)
This should be easy enough to understand. It looks for the raw score (from C7) into the range we obtained earlier, times 1 to convert everything to number (you can't look up numbers and text and expect a match). So that if there's an exact match of a number, it will return the row number of the found raw score and feed it to the INDEX(). For example, if the first row is returned, we get:
=INDEX('Sheet'!A6:A36,1)
Which is 'Sheet'!B6. If however there's no match (i.e. the raw score cannot be found), MATCH will return an error. And that's when the second part of the IFERROR comes into play:
MATCH(
1,
IF(
1*LEFT(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)+1,
100
)>=C7,
1,
0
)
,0
)
This MATCH tries to find 1 within what seems to be two IFs; the first one being:
IF( 1*LEFT('Sheet'!B6:B36,FIND("-",'Sheet'!B6:B36)-1)<=C7 , 1 , 0)
FIND("-",'Sheet'!B6:B36)-1 gets the position of the last character before the - in the column 'Sheet'!B6:B36.
With those values, this FIND would return:
12-13 -> 2
145-155 -> 3
1567-1865 -> 4
The IF thus becomes:
IF( 1*LEFT('Sheet'!B6:B36,{2,3,4})<=C7 , 1 , 0)
Notice the braces here; they indicate an array and that's why this is an array formula. LEFT then extracts all the characters before the - (remember your other question, I answered with a technique very similar to this):
12-13 -> 2 -> 12
145-155 -> 3 -> 145
1567-1865 -> 4 -> 1567
Which is...
IF( 1*{12,145,1567}<=C7 , 1 , 0)
Again, 1* converts those to actual numbers because LEFT be default returns text characters. It's important here to do this because we're going to use the comparator <=, so that if the value to the left of C7 (the raw score), then the IF should return 1, else, it should return 0. Let's say that the raw score was 154. The results would be:
IF( {12,145,1567}<=154 , 1 , 0)
IF( {TRUE,TRUE,FALSE} , 1 , 0)
{1,1,0}
I just realised that the formula can be made a little shorter xD Anyway, we'll see that later. The next IF behaves in a similar fashion, but checks for the value at the right of the -:
IF( 1*MID('Sheet'!B6:B36,FIND("-",'Sheet'!B6:B36)+1,100)>=C7 , 1 , 0)
With...
FIND MID('Sheet'!B6:B36, X, 100)
12-13 -> 4 -> 13
145-155 -> 5 -> 155
1567-1865 -> 6 -> 1865
You can notice that this formula will stop working if you have something above 100 character long here. Anyway, the IF thus becomes:
IF( {13,155,1865}>=154 , 1 , 0)
IF( {FALSE,TRUE,TRUE} , 1 , 0)
{0,1,1}
Now that we have these, the MATCH from before becomes:
MATCH( 1 , {1,1,0}*{0,1,1} , 0)
Some simple math makes this into:
MATCH( 1 , {0,1,0} , 0)
And what is the position of the 1 in there? That's right, position 2!
Our original formula this becomes:
=INDEX( 'Sheet'!A6:A36 , IFERROR( #Error! , 2 ) )
So that if nothing was found at first, it will return an error (#N/A in this case) and instead return 2. =INDEX( 'Sheet'!A6:A36 , 2 ) gives 'Sheet'!A7.
And the slightly shorter version is:
=INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!A6:A36"),IFERROR(MATCH(C7,INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0))*1,0),MATCH(1,(1*LEFT(INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)))-1)<=C7)*(1*MID(INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP($B$5,TblA)&"'!B5:J5"),0)))+1,100)>=C7),0)))
I actually removed the inner IFs, because (a>b)*(c>b) already returns 0s and 1s since TRUE multiplied by TRUE gives 1 in excel.

In Excel 2007 the formulae are returning a lot of circular reference warnings, so it may be worth adding a tag for your Excel version. Mine is Excel 2007 but with it the results you want seem achievable as below:
To shorten the formulae and reduce computation I have added in Report C5 "Table" and in D5 =VLOOKUP(B5,TblA,2,1).
I have also inserted a column immediately to the right of ColumnH ("ColD") in 5.2.0 to 5.7.30 and applied Text To Columns on Column H, with - as the delimiter.
I then applied to Report E7 and copied down to E15:
=INDEX(INDIRECT("'"&D$5&"'!A6:A36"),MATCH(C7,INDIRECT("'"&D$5&"'!"&CHAR(ROW()+59)&"6:"&CHAR(ROW()+59)&"36"),0))
and adjusted the 59s to 60s in the last three rows. Such adjustment would not be necessary if ColumnI were moved far enough to the right.
In E13 I changed the match from exact to next higher (final 0 to -1).
For Figures I cheated and changed K23 in 5.2.0 to 5.7.30 to 22 from 21-22, but such banding could, for other columns, be treated in much the same way as I did for ColD.

Resources