If multiple criteria - excel

Question

I am currently working on a multiple if, I would like to avoid writing 100 "OR" in my code and therefore I have a list of criterias (AO450 to AO515) and I would like to have something like this : If the cells(i, 33) like one of the criterias, then "comment", your help would be very welcomed :)
Sub MultipleIf()
For i = 3 To 467
If Cells(i, 19).Value > 5000 Then
If Cells(i, 33).Value Like "*" & "Cells(AO450:AO515).Value" & "*" Then
Cells(i, 35).Value = "commentA"
ElseIf Cells(i, 19).Value > 0 And Cells(i, 33).Value Like "*" & "ABC" & "*" Then
Cells(i, 35).Value = "commentB"
ElseIf Cells(i, 19).Value > 0 And Cells(i, 33).Value Like "*" & "DEF" & "*" Then
Cells(i, 35).Value = "commentC"
Else
Cells(i, 35).Value = "commentD"
End If
ElseIf Cells(i, 19).Value < -5000 Then
If Cells(i, 33).Value Like "*" & "Cells(AO450:AO515).Value" & "*" Then
Cells(i, 35).Value = "commentAA"
ElseIf Cells(i, 19).Value < 0 And Cells(i, 33).Value Like "*" & "ABC" & "*" Then
Cells(i, 35).Value = "commentBB"
ElseIf Cells(i, 19).Value < 0 And Cells(i, 33).Value Like "*" & "DEF" & "*" Then
Cells(i, 35).Value = "commentC"
Else
Cells(i, 35).Value = "commentD"
End If
Else:
If Cells(i, 19).Value < 0 And Cells(i, 33).Value Like "*" & "GHI" & "*" Then
Cells(i, 35).Value = "commentE"
Cells(i, 36).Value = "commentF"
Else
Cells(i, 35).Value = "commentD"
End If
End If
Next
End Sub

Answer 1

EDIT - updated to add full (reworked) code
If you want to test whether a value is found in a single-column range then you can do something like this:
Sub MultipleIf()
'come up with some better variable names than `v19` and `v33`...
Dim ws As Worksheet, i As Long, rw As Range, v19, v33 As String, rngList As Range, txt
Set ws = ActiveSheet
Set rngList = ws.Range("AO450:AO515")
For i = 3 To 467
Set rw = ws.Rows(i)
v19 = rw.Cells(19).Value
v33 = rw.Cells(33).Value
txt = ""
If v19 > 5000 Then
Select Case True 'https://stackoverflow.com/questions/794036/select-case-true
Case ColumnContains(rngList, v33): txt = "commentA"
Case v33 Like "*ABC*": txt = "commentB"
Case v33 Like "*DEF*": txt = "commentC"
Case Else: txt = "commentD"
End Select
ElseIf v19 < -5000 Then
Select Case True
Case ColumnContains(rngList, v33): txt = "commentAA"
Case v33 Like "*ABC*": txt = "commentBB"
Case v33 Like "*DEF*": txt = "commentC"
Case Else: txt = "commentD"
End Select
Else
If v19 < 0 And v33 Like "*GHI*" Then
txt = "commentE"
rw.Cells(36).Value = "commentF"
Else
txt = "commentD"
End If
End If
If Len(txt) > 0 Then rw.Cells(35).Value = txt
Next
End Sub
'does a (single-column) range `rng` contain the string `txt`?
Function ColumnContains(rng As Range, txt As String) As Boolean
ColumnContains = Not IsError(Application.Match("*" & txt & "*", rng, 0))
End Function