Search for specific words and replace each with a corresponding different word? - excel

Question

I need to search through a range.
If 5062 is found change to 3201, 5063 to 3202, and 5084 to 3204.
Dim myRange As Range
Set myRange = Range(Cells(6, 3), Cells(65, 3))
With myRange.Find
.Execute FindText:="5062", ReplaceWith:="3201"
.Execute FindText:="5063", ReplaceWith:="3202"
.Execute FindText:="5084", ReplaceWith:="3204"
End With
End Sub

Answer 1

Here, try this:
Sub ReplaceValues()
Dim SearchReplaceArray
Dim I As Long
Dim RG As Range
Set RG = Range("A1:O34")
'Array Storage: <_Array_First_Row__> <___Second_Row_____>
SearchReplaceArray = [{"5062","5063","5084";"3201","3202","3204"}]
For I = 1 To UBound(SearchReplaceArray, 2)
RG.Replace _
What:=SearchReplaceArray(1, I), _
Replacement:=SearchReplaceArray(2, I), _
LookAt:=xlWhole, _
MatchCase:=True
Next I
End Sub
Very easy to modify for any number of replacements.
Makes replacements very quickly.
Turns this:
Into This:
I speed tested it like this... because curiosity:
Sub TestSpeed()
Dim SearchReplaceArray
Dim I As Long
Dim Start
Dim RG As Range
Set RG = Range("A1:J10000")
Start = Timer
'Array Storage: <_Array_First_Row__> <___Second_Row_____>
SearchReplaceArray = [{"5062","5063","5084";"3201","3202","3204"}]
For I = 1 To UBound(SearchReplaceArray, 2)
RG.Replace _
What:=SearchReplaceArray(1, I), _
Replacement:=SearchReplaceArray(2, I), _
LookAt:=xlWhole, _
MatchCase:=True
Next I
Debug.Print "Completed " & RG.Cells.Count & " replacements in " & Timer - Start & " seconds."
End Sub
Every single cell had one of the three values required to replace.
The debug output was:
Completed 100000 replacements in 3.027344 seconds.
Completed 100000 replacements in 2.976563 seconds.
Completed 100000 replacements in 2.996094 seconds.
Completed 100000 replacements in 2.976563 seconds.
Completed 100000 replacements in 3.070313 seconds.
Not bad.

Answer 2

I have made a loop which searches the range provided in your question for the given values. If the value is the value of a cell in the range, it is replaced with the intended value. Hope this helps!
Sub FindVals()
Dim myRange As Range
Set myRange = Range(Cells(6, 3), Cells(65, 3))
Dim chngVal1 As Integer, chngVal2 As Integer, chngVal3 As Integer
chngVal1 = 3201
chngVal2 = 3202
chngVal3 = 3204
For Each cell In myRange
If cell.Value = 5062 Then cell.Value = chngVal1
If cell.Value = 5063 Then cell.Value = chngVal2
If cell.Value = 5084 Then cell.Value = chngVal3
Next
End Sub