How to avoid using transpose when putting values from array to column - excel

Question

I'm getting data in a collection from a web request and I need to put it into a column. While this function does what it needs, it is slow. I have already set xlCalculationManual in an earlier function and ScreenUpdating and EnableEvents did not affect much.
I need to run the data inserts in batches of 15000 because transpose returns only about 17900 first items. But could I build the array in CollectionToArray function in such a way that I don't need to transpose it? I tried to make it return a two dimensional array and put the values to the second dimension, but it did not work. I still needed to transpose it, or all the rows in the column had the first element of the array.
Function replaceList(startCol As Integer, endCol As Integer, values As Collection)
Dim batch As Long
Dim batchStart As Long
Dim batchEnd As Long
Dim b As Long
batch = 15000
With Worksheets("MyData")
Do While b * batch < values.Count
If (b + 1) * batch > values.Count Then
batchEnd = values.Count
Else
batchEnd = (b + 1) * batch
End If
batchStart = b * batch + 1
.Range(.Cells(batchStart + 2, startCol), .Cells(batchEnd + 2, endCol)).Value = Application.Transpose(CollectionToArray(values, batchStart, batchEnd))
b = b + 1
Loop
End With
End Function
Function CollectionToArray(C As Collection, batchStart As Long, batchEnd As Long) As Variant()
Dim a() As Variant: ReDim a(0 To (batchEnd - batchStart))
Dim i As Long
Dim j As Integer
j = 0
For i = batchStart To batchEnd
a(j) = C.item(i)
j = j + 1
Next
CollectionToArray = a
End Function

Answer 1

Write Collection Values to a Worksheet Column
Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Purpose: Writes the numbers from one to a million to a collection
' and returns the values of the collection in a one-column range.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Calls: 'WriteCollectionToColumnRange'
' 'GetCollection'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub CollectionToColumnExample()
Dim wb As Workbook: Set wb = ThisWorkbook
Dim ws As Worksheet: Set ws = wb.Worksheets("MyData")
Dim fCell As Range: Set fCell = ws.Range("A2")
' Populate collection with dummy data.
Dim coll As Collection: Set coll = New Collection
Dim n As Long
For n = 1 To 1000000
coll.Add n
Next n
' Write the values to a range.
WriteCollectionToColumnRange fCell, coll
End Sub
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Purpose: Returns the values of a collection in a one-column range.
' Calls: 'GetCollection'.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub WriteCollectionToColumnRange( _
ByVal FirstCell As Range, _
ByVal coll As Object)
Dim Data As Variant: Data = GetCollection(coll)
Dim rg As Range: Set rg = FirstCell.Resize(UBound(Data, 1), 1)
rg.Value = Data
End Sub
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Returns the values from a collection in a 2D one-based one-column array.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function GetCollection( _
ByVal coll As Collection) _
As Variant
Dim Data As Variant: ReDim Data(1 To coll.Count, 1 To 1)
Dim Item As Variant
Dim r As Long
For Each Item In coll
r = r + 1
Data(r, 1) = Item
Next Item
GetCollection = Data
End Function