Sum numbers in cell containing text without spaces - excel

Question

I have done extensive research on SO and google but not coming up with a solution.
While this question may have been asked earlier, my situation is slightly different
The function works fine if there is a space between the text and numbers. However, does not work if there aren't any spaces.
Function SumNumbers(rngS As Range, Optional strDelim As String = " ") As Double
Dim xNums As Variant, lngNum As Long
xNums = Split(rngS, strDelim)
For lngNum = LBound(xNums) To UBound(xNums) Step 1
SumNumbers = SumNumbers + Val(xNums(lngNum))
Next lngNum
End Function
My cell data looks like this: su9m11w11.5th8
I tried adding an alphabet array, but had no luck. Help is welcome.
strDelim = Array("F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "U")

Answer 1

Well, depening on your data, you could try:
Sub Test()
Dim StrIn As String: StrIn = "su9m11w11.5th8"
Debug.Print SumDigits(StrIn)
End Sub
Function SumDigits(str As String) As Double
With CreateObject("vbscript.regexp")
.Global = True
.Pattern = "[a-z]+"
SumDigits = Application.Evaluate(.Replace(str, "+") & ".0")
End With
End Function
Here I used a regular expression to substitute all the lowercase characters ranging a-z for a "+". The resulting string then can be evaluated to return the sum.
EDIT:
Another way could be to use a regular expression that will return all the possible (negative) numbers, and sum those:
Function SumDigits(str As String) As Double
With CreateObject("vbscript.regexp")
.Global = True
.Pattern = "-?\d+(?:\.\d+)?"
If .Test(str) Then
For Each Match In .Execute(str)
SumDigits = SumDigits + Match
Next
End If
End With
EDIT 2:
To return an average we should capture the amount of matching substrings and devide the sum by that count:
Function SumDigits(str As String, Optional avg As Boolean) As Double
With CreateObject("vbscript.regexp")
.Global = True
.Pattern = "-?\d+(?:\.\d+)?"
If .Test(str) Then
Set Matches = .Execute(str)
For Each Match In Matches
SumDigits = SumDigits + Match
Next
If avg Then SumDigits = SumDigits / Matches.Count
End If
End With
End Function
Call using Debug.Print SumDigits(StrIn, True) instead.

Answer 2

Here is a VBA function to produce either the sum or the average of your embedded numbers... and it handles negatives as well. And this is pure Excel VBA with no references to outside libraries:
Function SumEmbeddedNumbers#(s$, Optional bAverage As Boolean)
Dim i&, p&, max&, t&, pluses&
Dim b() As Byte, res() As Byte
Static keep() As Boolean
Const VALS$ = "0123456789.-"
If (Not Not keep) = 0 Then
ReDim keep(0 To 255)
For i = 1 To Len(VALS)
keep(Asc(Mid$(VALS, i, 1))) = 1
Next
End If
max = LenB(s)
ReDim res(0 To max)
b = StrConv(s, vbFromUnicode)
For i = 0 To Len(s) - 1
t = b(i)
If keep(t) Then
res(p) = t
p = p + 1
Else
If p Then
If res(p - 1) <> 43 Then
res(p) = 43
pluses = pluses + 1
p = p + 1
End If
End If
End If
Next
SumEmbeddedNumbers = Evaluate(Left$(StrConv(res, vbUnicode), p))
If bAverage Then SumEmbeddedNumbers = SumEmbeddedNumbers / (pluses + 1)
End Function
MsgBox SumEmbeddedNumbers("su9m11w11.5th8") '<---displays: 39.5
MsgBox SumEmbeddedNumbers("su9m11w11.5th8", True) '<---displays: 9.875