Using Excel to GROUP BY and find date WHERE MAX - excel

Question

My problem is I have a table of data structured as below :
+---------------+------------+---------+
| recipe number | date | quality |
+---------------+------------+---------+
| 154 | 01/01/2020 | 2 |
| 154 | 01/03/2020 | 3 |
| 154 | 01/05/2020 | 1 |
| 154 | 01/07/2020 | 2 |
| 222 | 01/01/2020 | 3 |
| 222 | 01/03/2020 | 2 |
| 222 | 01/05/2020 | 2 |
| 222 | 01/07/2020 | 1 |
| 888 | 01/01/2020 | 1 |
| 888 | 01/03/2020 | 3 |
| 888 | 01/05/2020 | 2 |
| 888 | 01/07/2020 | 3 |
| 666 | 01/01/2020 | 2 |
| 666 | 01/03/2020 | 3 |
| 666 | 01/05/2020 | 3 |
| 666 | 01/07/2020 | 3 |
| 777 | 01/01/2020 | 1 |
| 777 | 01/03/2020 | 2 |
| 777 | 01/05/2020 | 3 |
| 777 | 01/07/2020 | 1 |
| 123 | 01/09/2020 | 3 |
| 254 | 01/01/2020 | 2 |
| 254 | 01/03/2020 | 3 |
| 745 | 01/01/2020 | 1 |
| 745 | 01/03/2020 | 3 |
| 745 | 01/05/2020 | 2 |
| 745 | 01/07/2020 | 3 |
| 578 | 01/11/2020 | 3 |
| 578 | 01/01/2021 | 3 |
| 578 | 01/03/2021 | 1 |
| 578 | 01/05/2021 | 3 |
| 678 | 01/07/2021 | 2 |
| 999 | 01/09/2021 | 1 |
| 999 | 01/11/2021 | 1 |
+---------------+------------+---------+
The final answer I want is that I need a table of each recipe number and a simple yes/no whether that recipe decreased in quality over time, at all.
There are some recipes which only have one entry, and others which only increased in quality - these need to be answered "no"
EG:
recipe
decreased?
154
yes
666
no
Unfortunately, I'm limited to only Excel for this, though I understand doing it in other environments is probably easier.
I have tried a max(index+match) to see if I can return the highest quality for each recipe (and the lowest with a min). But I got stuck at trying to get Excel to return an array of qualities conditional on which recipe to look at.
I also tried PowerQuery but the problem seems too complex for that utility.
I've done some more thinking and some psuedocode that would solve it is:
For each recipe number:
1) Find me the max quality and the date where it happened
2) Find me any quality lower than this number where the date it happened is
after step 1
3) If the date of step 1 is earlier (less than) the date of step 2, output
"yes", otherwise "no"
Translating that into Excel 2016 is a bit difficult

Answer 1

Edit: Thanks to #TomSharpe who pointed out some logic errors => incorrect results, I have had to modify the M-code and also remove the formula method. I believe the code below satisfies your requirements
This can be done in Power Query
Group by Recipe
Determine the first date of the highest quality
See if any dates after the first date have a lower quality
If so then "yes" else "no"
Examine the comments and step through the Applied Steps window to better understand the algorithm.
M Code
let
//read in the data
//change table name in next line to actual table name
Source = Excel.CurrentWorkbook(){[Name="Table18"]}[Content],
//set data types
#"Changed Type" = Table.TransformColumnTypes(Source,{{"recipe number", Int64.Type}, {"date", type date}, {"quality", Int64.Type}}),
//group by recipe number
#"Grouped Rows" = Table.Group(#"Changed Type", {"recipe number"}, {
//(t) is each subtable returned
{"Quality Decrease", (t)=>
let
//List.Max(quality) => highest quality rating
//Filter the subtable to only show qualities of that value
//then, with List.Min(....[date]) return the earliest date
firstBest= List.Min(Table.SelectRows(t, each [quality] = List.Max(t[quality]))[date]),
//Filter the subtable to only show dates > firstBest date and with quality worse than the highest quality rating
decrQual = Table.SelectRows(t, each [date] > firstBest and [quality] < List.Max(t[quality]))
in
//check if resultant table is empty
if Table.IsEmpty(decrQual) then "no" else "yes", Text.Type
}
})
in
#"Grouped Rows"