Passing a different function into the same iteration loop (VBA) - excel

Question

My overall goal is to translate an Excel based financial model into VBA. The financial model has a number of scenarios (e.g. 3) and development types (e.g. 3 - residential, commercial, industrial). There are two components of the model - revenue and costs - at present but my solution needs to be massively scalable.
The revenue calculation will be the same for each of the nine instances but the inputs will change. I am taking the inputs from the workbook and placing them in collections. I add the result of the calculation to another collection. The costs calculation will be different but will use the exact same iteration loops.
What I'm trying to do is write the iteration code once but pass a different calculation to the loop. I've done it as follows by coding the formula in a Class Object and then passing the Class Object into a function. Please see below a sandbox example.
' Passing different classes into iteration loop
Sub Main()
Dim clsAdd As CAdd
Dim colAdd As Collection
Set clsAdd = New CAdd
Set colAdd = New Collection
Set colAdd = Iteration(clsAdd)
Dim clsMul As CMult
Dim colMul As Collection
Set clsMul = New CMult
Set colMul = New Collection
Set colMul = Iteration(clsMul)
End Sub
' Same iteration loop required for different calculations
Function Iteration(ByRef colClass As Object) As Collection
Dim varArray01() As Variant
Dim varArray02() As Variant
Dim itA As Integer
Set Iteration = New Collection
varArray01 = Array(1, 2, 3, 4)
varArray02 = Array(11, 12, 13, 14)
For itA = 0 To UBound(varArray01)
Iteration.Add colClass.ICalculation_Calculation(varArray01(itA), varArray02(itA))
Next itA
End Function
'Add Class
Public Function Calculation(ByVal intA As Integer, ByVal intB As Integer) As Integer
Calculation = intA + intB
End Function
'Multiply Class
Public Function Calculation(ByVal intA As Integer, ByVal intB As Integer) As Integer
Calculation = intA * intB
End Function
Although this works, I feel that there must be a better solution than creating a new Class Object for each formula I want because every formula must be calculated using the a function called 'Calculation'. Your suggestions are most welcome.

Answer 1

You apparently already have an interface defined for your calculation classes. Just change the parameter of Iteration to take the interface directly.
You have implemented the Command design pattern. Small, single purpose Command objects (your CAdd and CMult) are (IMO) good design..I wouldn't try to convince you to take a different approach.
' Same iteration loop required for different calculations
Function Iteration(ByRef calculator As ICalculation) As Collection
Dim varArray01() As Variant
Dim varArray02() As Variant
Dim itA As Integer
Set Iteration = New Collection
varArray01 = Array(1, 2, 3, 4)
varArray02 = Array(11, 12, 13, 14)
For itA = 0 To UBound(varArray01)
Iteration.Add calculator.Calculation(varArray01(itA), varArray02(itA))
Next itA
End Function
Sub Main becomes:
' Passing different classes into iteration loop
Sub Main()
Dim colAdd As Collection
Set colAdd = Iteration(New CAdd)
Dim colMul As Collection
Set colMul = Iteration(New CMult)
End Sub
If creating several small, 'stateless' classes is not the kind of solution you are looking for, then the Command pattern can also be implemented using a single Class that contains a minimal amount of 'state'.
using a class like Calculator below:
Option Explicit
Implements ICalculation
Public Enum CalcID
Add
Multiply
End Enum
Private mCalculationID As CalcID
Private Sub Class_Initialize()
mCalculationID = Add
End Sub
Public Property Get CalculationID() As CalcID
CalculationID = mCalculationID
End Property
Public Property Let CalculationID(ByVal RHS As CalcID)
Select Case RHS
Case Add, Multiply
mCalculationID = RHS
Case Else
Err.Raise -1, "Invalid calculationID: " & CStr(RHS)
End Select
End Property
Private Function ICalculation_Calculation(ByVal intA As Integer, ByVal intB As Integer) As Integer
Select Case mCalculationID
Case Multiply
ICalculation_Calculation = intA * intB
Case Add
ICalculation_Calculation = intA + intB
Case Else
'Raise an error
End Select
End Function
Now you have one calculator class to manage...and the calling module(s) are responsible for managing the calculator's configuration. The Main subroutine changes slightly and the Iteration function remains unchanged.
Sub Main()
Dim calc As Calculator
Set calc = New Calculator
calc.CalculationID = CalcID.Add
Dim colAdd As Collection
Set colAdd = Iteration(calc)
calc.CalculationID = CalcID.Multiply
Dim colMul As Collection
Set colMul = Iteration(calc)
End Sub