Excel: running maximum of two rows, or just return value in one row - excel

Question

I have an Excel spreadsheet:
Name
Grade
Name1
82
Name1
90
Name2
65
Name3
90
Name3
60
I would like an Excel command that will do the following in a new column (TrueGrade, column C):
If a string occurs twice in column A (Name)
then get the maximum of the two values from column B (Grade)
else get the value from column B in the same row as the name (which only occurs once).
This is what the result should look like:
Name
Grade
TrueGrade
Name1
82
90
Name1
90
Name2
65
65
Name3
90
90
Name3
60
Unfortunately, vlookup does not return multiple values.
So far, I have tried this in cell C2:
=INDEX($A$2:$B$5, SMALL(IF($A$2:$A$5=B2, ROW($A$2:$A$5)), ROW(1:1))-1,COLUMNS($A$2:$B$5))
which gave me 82, but this is just the first instance of a grade for Name1.

Answer 1

Using your test data as an example, putting this formula in C2 and copying down gave me your expected results:
=IF(COUNTIF(A$2:A2,A2)>1,"",MAXIFS(B$2:B$6,A$2:A$6,A2))
Obviously extend the ranges to suit your situation. Also note that the CountIF formula range is slightly different than the Maxifs formula. This also assumes you have the MaxIfS formula. If you don't you can do the same thing with an array formula:
=IF(COUNTIF(A$2:A2,A2)>1,"",MAX(IF(A2=A2:A6,B2:B6)))
Just remember to confirm the array formula with Ctrl+Shift+Enter.

Answer 2

I like to use SUMPRODUCT in these cases (because I always forget to properly enter array formulas).
So in cell C2, you can use:
=SUMPRODUCT(MAX(($A$2:$A$6=A2)*($B$2:$B$6)))
EDIT: late with the updated answer based on my earlier work but it's the same as #sous2817:
=IF(COUNTIFS(OFFSET($A$2,0,0,ROW()-ROW($A$2)+1,1),$A2)=1,SUMPRODUCT(MAX(($A$2:$A$6=A2)*($B$2:$B$6))),"")
This still works without an array formula.