Excel VBA: Show/Hide Pictures on yes/no dropdowns; troubleshooting simultaneous .Visible? - excel

Question

Forgive me, I know nothing about VBA and I had the crazy idea to make Xmas presents that digitally replicate a scratch-off bucket list or novelogue poster in Excel. After lots of frustration, I got as far as being able to turn on/off a picture with an individual dropdown ("Unread"/"Complete"). It's a big table of book titles with book covers hidden until each one is marked Complete, then that book cover should display.
The problem is that only one image will show at a time. If two books are marked complete, only the most recent changed to Complete will be visible. Is this because I have them all running in the same Sub? Do I need a separate Sub for every image (that would be 100 Subs)?
Snippet, let's say there were only 5 books:
Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("B4")) Is Nothing Then
Shapes("Picture 1").Visible = Range("B4").Value = "Complete"
Else
Shapes("Picture 1").Visible = False
End If
If Not Intersect(Target, Range("D4")) Is Nothing Then
Shapes("Picture 2").Visible = Range("D4").Value = "Complete"
Else
Shapes("Picture 2").Visible = False
End If
If Not Intersect(Target, Range("F4")) Is Nothing Then
Shapes("Picture 3").Visible = Range("F4").Value = "Complete"
Else
Shapes("Picture 3").Visible = False
End If
If Not Intersect(Target, Range("H4")) Is Nothing Then
Shapes("Picture 4").Visible = Range("H4").Value = "Complete"
Else
Shapes("Picture 4").Visible = False
End If
If Not Intersect(Target, Range("J4")) Is Nothing Then
Shapes("Picture 5").Visible = Range("J4").Value = "Complete"
Else
Shapes("Picture 5").Visible = False
End If
End Sub
I'm sure there's some more efficient way to do this but I'm more concerned with getting the images to show independently of other images' visible values. Thanks!
EDIT: I'm sorry my explanation wasn't clear enough. I don't have enough reputation to share an image, unfortunately. There are 10 columns of book covers, and 10 rows. Every other column holds images (in between is spacer). See below for rows.
When marked "Unread" in the cell below, the image should be hidden. When marked "Complete" below, the image should be revealed.
To explain cell layout:
B2 holds the image
B3 holds the title
B4 holds the data validated dropdown (that VBA checks for B2's image value of visible)
Spreadsheet layout:
B2:T2 have the first 10 images and thus,
B4:T4 have the first 10 data validated dropdowns
B7:T7 next dropdowns
B10:T10 " "
B13:T13, then B16:T16, B19:T19, B22:T22, B25:T25, B28:T28, B31:T31
https://i.imgur.com/RKC5AzG.png

Answer 1

I'm not 100% sure if I understood your question correctly but I tried just putting the repetitive parts of your code into a loop. Also, it will now not turn pictures invisible again.
If you are unfamiliar with the Cells property I used, you can find more information on it here.
Also, I split up this piece of code:
Shapes("Picture 1").Visible = Range("B4").Value = "Complete"
How was that supposed to work? I guess you wanted the picture to be visible and the cell to show "Complete"...
The picture name inside the loop is created by string concatenation from "Picture " & i
Private Sub Worksheet_Change(ByVal Target As Range)
Dim i as Long
Dim totalNumberOfPictures as Long
totalNumberOfPictures = 8 'Input number of pictures you have here
For i=1 To totalNumberOfPictures
If Not Intersect(Target, Cells(4, 2 * i)) Is Nothing Then
Shapes("Picture " & i).Visible = True
Cells(4, 2 * i) = "Complete"
End If
Next i
End Sub
Or if you meant every picture where the assigned cells value is changed to "Complete" should be visible, you can try this:
Edit: Updated to address the added detail in your question...
Private Sub Worksheet_Change(ByVal Target As Range)
Dim i as Long
Dim totalNumberOfPictures as Long
Dim count as Long
Dim rowOffset as Long
totalNumberOfPictures = 100 'Input number of pictures you have here
count = 1
rowOffset = 0
For i=1 To totalNumberOfPictures
If Cells(4 + rowOffset, 2 * count) = "Complete" Then
Shapes("Picture " & i).Visible = True
Else
Shapes("Picture " & i).Visible = False
End If
If count = 10 Then ' 10 is the number of pictures per "row"
rowOffset = rowOffset + 3 ' 3 is the row difference between your dropdown rows
count = 0
End if
count = count+ 1
Next i
End Sub
Let me know if it works, or if this is not what you meant, what you actually want...

Answer 2

If it was my project, I’d do it a slightly different way. I’ll offer this as a suggestion – let me know if it doesn’t suit you & I’ll delete it.
Step 1 – rename the pictures to match the book titles. This will be tiresome to start with, but it means you won’t be tied to a loop based on “Picture #” because picture names can vary. Also makes the names more intuitive.
Step 2 – copy the code below into a standard module & run it when you’re on the sheet with the pictures. It will create a named, non-contiguous range. If you look at the code, it’s fairly obvious how you can adjust it over time to suit your changing needs. Simply add more ranges as you need and rerun it.
Sub MakeRangeName()
ActiveSheet.Range _
("B4:T4,B7:T7,B10:T10,B13:T13,B16:T16,B19:T19,B22:T22,B25:T25,B28:T28,B31:T31") _
.Name = "myRange"
End Sub
Step 3 – copy the code below to the Sheet code module where you have the pictures. It will run whenever there’s a change in the range you created in Step 2, but will only affect the actual picture of interest.
Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo GetOut
Application.EnableEvents = False
Dim s As String
If Not Intersect(Range("myRange"), Target) Is Nothing Then
If ActiveCell.Offset(-1, 0) = "" Then GoTo Letscontinue '<< to ignore the inbetween columns
s = ActiveCell.Offset(-1, 0).Text
If ActiveCell.Value = "Complete" Then
ActiveSheet.Shapes(s).Visible = True
Else
ActiveSheet.Shapes(s).Visible = False
End If
End If
Letscontinue:
Application.EnableEvents = True
Exit Sub
GetOut:
MsgBox Err.Description
Resume Letscontinue
End Sub
I’ve tested it and it works for me. Let me know if you get stuck on anything.