Change specific characters in just part of a cell - excel

Question

I'd like to change a specific in text, so I need to find all ";" characters and change them to "$" but only if they are in bracket(s).
So, there can be few cases:
example 1
text (it's ok; it's not ok); ok
should be:
text (it's ok$ it's not ok); ok
example 2
text (it's ok; it's not ok); ok (tekst;) ok
should be:
text (it's ok$ it's not ok); ok (tekst$) ok
example 3
text (it's ok; (ok;)it's not ok);
should be:
text (it's ok$ (ok$)it's not ok);
so I've started with replacing strings code, but problem is that my code now replace characters even after ")" and I don't want that.
should I somehow counts string that need to be changed and set start position and change only them? But then problem is if we have more brackets, it will not work.
what would be best way to do it?
Sub Removetext()
s = Range("A1").Value
Dim start As Integer
Dim end1 As Integer
start = InStr(1, s, "(")
end1 = InStr(1, s, ")")
s = Left(s, start - 1) & Replace(s, ";", "$", start)
End Sub

Answer 1

Here's one way, avoiding regexp as I don't use it enough to be able to remember how to do it without a lot of effort.
Sub x()
Dim i As Long, lb As Long, rb As Long, r As Range
Range("A1:A4").Copy Range("B1")
For Each r In Range("B1:B4")
For i = 1 To Len(r.Value)
If Mid(r, i, 1) = "(" Then lb = lb + 1
If Mid(r, i, 1) = ")" Then rb = rb + 1
If Mid(r, i, 1) = ";" Then
If lb > 0 And rb < lb Then r.Characters(i, 1).Text = "$"
End If
Next i
Next r
End Sub

Answer 2

Replace Between Chars (UDF)
If there are more occurrences of LeftChar (opening parentheses) than of RightChar (closing parentheses) to the left of
FindChar, FindChar will be replaced with ReplaceChar.
In Excel, for a string in A1 you can use it like this:
=RBC(A1)
In VBA see below.
The Code
Option Explicit
Function RBC( _
ByVal aString As String, _
Optional ByVal LeftChar As String = "(", _
Optional ByVal RightChar As String = ")", _
Optional ByVal FindChar As String = ";", _
Optional ByVal ReplaceChar As String = "$") _
As String
If Len(aString) > 0 Then
Dim Parts() As String
Parts = Split(aString, FindChar)
Dim Result As String
Result = Parts(0)
Dim cLen As Long
Dim lCount As Long
Dim rCount As Long
Dim n As Long
For n = 1 To UBound(Parts)
cLen = Len(Result)
lCount = cLen - Len(Replace(Result, LeftChar, ""))
rCount = cLen - Len(Replace(Result, RightChar, ""))
If lCount > rCount Then
Result = Result & ReplaceChar & Parts(n)
Else
Result = Result & FindChar & Parts(n)
End If
Next n
RBC = Result
End If
End Function
Sub testRBC()
Const aString As String = "(it's ok; (ok;)it's not; ok);"
Debug.Print RBC(aString)
End Sub
' Results in column B:
Sub testRBC2()
Dim rng As Range
Set rng = Range("A1:A100000")
Dim Data As Variant
Data = rng.Value
Dim i As Long
For i = 1 To UBound(Data, 1)
Data(i, 1) = RBC(Data(i, 1))
Next i
rng.Offset(, 1).Value = Data
End Sub