Reconciling Columns VBA - excel

Question

I'm looking to create a reconciliation sub which will find a value in Spreadsheet A, Column A and return the corresponding value in Column B i.e. Column A = ID123; Column B = HELLO. The procedure will then find the same value in Spreadsheet B, Column A (in this example, ID123) and return the value in Column B. So ideally, I would like these 2 values to be side by side so that I can do a comparison. All I have so far is code that will return values from Column A but I am unable to return Column B. This is essentially a VLookup, but Vlookups have proven to be very consuming in VBA:
Sub findCell()
Dim ETLCell As String
Dim mifidCell As String
Dim last_row_A As Long
Dim last_row_B As Long
last_row_A = Worksheets("Spreadsheet A").UsedRange.Rows.Count
last_row_B = Worksheets("Spreadsheet B").UsedRange.Rows.Count
'Loop which returns the TRN beside each column
For i = 2 To last_row_A
ETLCell = Worksheets("Spreadsheet B").Columns("B:B").Find(What:=Worksheets("Spreadsheet A").Cells(i, 1).Value)
mifidCell = Worksheets("Spreadsheet A").Cells(i, 1).Value
Worksheets("Reconciliation").Cells(i, 1).Value = ETLCell
If ETLCell Is Nothing Then
ETLCell = "BLANK"
Worksheets("Reconciliation").Cells(i, 2).Value = "False"
Else
Worksheets("Reconciliation").Cells(i, 2).Value = "True"
End If
Next i
End Sub

Answer 1

I took a different approach than the one that you took to solve this issue. I tried embedding comments into the code to describe what is happening. Try reviewing it and see if you can incorporate it into your workbook, and write back with questions.
I stored the values from sheet B into a dictionary object for efficient lookup. This type of object holds a unique key, and a corresponding value. Then, I can loop over the Keys in sheet A, looking for them in sheet B, and then adding the values to the reconciliation.
Sub AnalyzeReconciliation()
Dim sht1 As Worksheet
Dim sht2 As Worksheet
Dim shtRecon As Worksheet
Dim rng1 As Range
Dim rng2 As Range
Dim cel As Range
Dim oDict As Object
Dim reconRow As Long
Set sht1 = Worksheets("Worksheet A")
Set sht2 = Worksheets("Worksheet B")
Set shtRecon = Worksheets("Reconciliation")
'I don't like using UsedRange. I find it to be unreliable
'Define the columns that you need, and find the last row
'using a method call similar to below
Set rng1 = sht1.Range("A2:B" & sht1.Range("A" & sht1.Rows.Count).End(xlUp).Row)
Set rng2 = sht2.Range("A2:B" & sht2.Range("A" & sht2.Rows.Count).End(xlUp).Row)
'Get a dictionary object holding unique values from sheet 2
'In my case, column A holds the Id, and column B holds the value
Set oDict = GetDictionary(rng2, 1, 2)
reconRow = 0
'Loop over each cel in sheet 1, column 1
'Look for the value in column 1 in the sheet 2 dictionary
'object, and then reconcile
For Each cel In Intersect(rng1, sht1.Columns(1))
'Get the next avail row in reconciliation sheet
reconRow = reconRow + 1
shtRecon.Range("A" & reconRow).Value = cel.Value
'Recon column B holds value from sheet 1, column B
shtRecon.Range("B" & reconRow).Value = cel.Offset(, 1).Value
'If Id is found in Sheet B dictionary, then take the value
'otherwise, write "blank" in column C
If oDict.exists(cel.Value) Then
shtRecon.Range("C" & reconRow).Value = oDict(cel.Value)
Else
shtRecon.Range("C" & reconRow).Value = "BLANK"
End If
Next cel
End Sub
'Function stores a range into a dictionary
'Param inputRange takes a range to be stored
'Param idColumn takes the column of the range to be used as the ID
' e.g. if idColumn = 2, and inputRange("C1:F10"), then column D
' is used for ID
'Param valueColumn points to the column in range used for the value
Function GetDictionary(inputRange As Range, idColumn As Long, valueColumn As Long) As Object
Dim oDict As Object
Dim sht As Worksheet
Dim cel As Range
Set oDict = CreateObject("Scripting.Dictionary")
Set sht = inputRange.Parent
For Each cel In Intersect(inputRange, inputRange.Columns(idColumn))
If Not oDict.exists(cel.Value) Then
oDict.Add cel.Value, sht.Cells(cel.Row, valueColumn).Value
End If
Next cel
Set GetDictionary = oDict
End Function