Disable a resource using count for specific environment with terraform - terraform

Question

I'm trying to disable a resource for a specific environment in this case its the qa environment, I only want the resource to be created for production and staging.
I have the same terraform code that runs for qa,staging and production via a pipeline.
I have some code used to create an ECS cluster. I don't want it to create for the qa environment.
This is the code that creates the cluster on ECS:
resource "aws_ecs_cluster" "main" {
name = "${terraform.workspace}-main"
tags = {
App = var.app_name
Environment = terraform.workspace
}
}
output "main_ecs_id" {
value = aws_ecs_cluster.main.id
}
I tried using count to disable the qa environment, and this works:
resource "aws_ecs_cluster" "main" {
count = terraform.workspace != "qa" ? 1 : 0
name = "${terraform.workspace}-main"
tags = {
App = var.app_name
Environment = aws_ecs_cluster.main[count.index].name
}
}
output "main_ecs_id" {
value = aws_ecs_cluster.main.*.id
}
Only issue is it doesn't work for the environment (production and staging) where I want the resource to create.
When it tries to create the resource with that code on production and staging then I get this error:
Error: Self-referential block
on ecs.tf line 8, in resource "aws_ecs_cluster" "main":
8: Environment = aws_ecs_cluster.main[count.index].name
Configuration for aws_ecs_cluster.main may not refer to itself.
Any idea what I could be doing wrong?
Thanks

Answer 1

Your issue isn't to do with disabling the resource with count, just that you can't refer to a resource inside itself (provisioners using the self keyword being the exception here but they're extra to the resource).
Instead you'd need to either build the name again or extract the name string into a local:
resource "aws_ecs_cluster" "main" {
count = terraform.workspace != "qa" ? 1 : 0
name = "${terraform.workspace}-main"
tags = {
App = var.app_name
Environment = "${terraform.workspace}-main"
}
}
or with a local:
locals {
cluster_name = "${terraform.workspace}-main"
}
resource "aws_ecs_cluster" "main" {
count = terraform.workspace != "qa" ? 1 : 0
name = local.cluster_name
tags = {
App = var.app_name
Environment = local.cluster_name
}
}
The use of locals only allows you to handle things that are known outside of the resource block (eg your string concatenation). If you wanted something that relied on the count or each in the resource block then you wouldn't be able to use that. There's an existing issue that covers resource scoped locals as an outstanding feature request.