Remove dot in string, issue with numbers < 1000 - excel

Question

I have a column with data taken from CSV file, the data contain the dot I need to remove. When I want to replace „.“(dot) with „“ (nothing) with VBA I have a wrong result. All numbers smaller than 1000 replace the comma, I have for example 122,49 and the result is 12249 which is wrong.
I tried several VBA codes, non of them worked.
If you can help me it would be great. I tried all options with formats..
Thank you.
2.078,00 -> 2078,00 ok
122,49 -> 12249 ko
328,28 -> 32828 ko
11.192,34 -> 11192,34 ok
Sub TEST()
Dim i As String
Dim k As String
i = "."
k = ""
Columns("P:P").Replace what:=i, replacement:=k, lookat:=xlPart, MatchCase:=False
End Sub

Answer 1

Actually this is a bug in Excel! It only happens in VBA. If you do the same replace from the user interface it works. The same from a recorded macro fails. So obviously a bug.
I recommend to read all the values into an array, then replace and then write them back. This way the error does not occur and using arrays is even faster than using ranges.
Option Explicit
Sub TEST()
Dim i As String
Dim k As String
i = "."
k = ""
Dim LastRow As Long 'find last used row (to reduce processed cells)
LastRow = Cells(Rows.Count, "P").End(xlUp).Row
Dim ReplaceValues() As Variant 'read all values into array
ReplaceValues = Range("P1:P" & LastRow).Value
Dim iRow As Long 'replace
For iRow = LBound(ReplaceValues) To UBound(ReplaceValues)
ReplaceValues(iRow, 1) = Replace(ReplaceValues(iRow, 1), i, k)
Next iRow
'write all values from array back into cells
Range("P1:P" & LastRow).Value = ReplaceValues
End Sub
Or, use Application.Substitute:
Sub Test()
Dim lr As Long
Dim arr As Variant
lr = Cells(Rows.Count, "P").End(xlUp).Row
arr = Range("P1:P" & lr).Value
Range("P1:P" & lr).Value = Application.Substitute(arr, ".", "")
End Sub

Answer 2

I'm not sure if I exactly understand your requirements, but see if this is doing what you want.
Function RemovePeriods(ByVal number As String) As String
RemovePeriods= Replace(number, ".", ",")
RemovePeriods= Replace(Left$(RemovePeriods, Len(number) - 3), ",", "") & Right$(RemovePeriods, 3)
End Function
'run from here
Sub Example()
Debug.Print RemovePeriods("2.078,00")
Debug.Print RemovePeriods("122,49")
Debug.Print RemovePeriods("328,28")
Debug.Print RemovePeriods("11.192,34")
End Sub
Output
2078,00
122,49
328,28
11192,34

Answer 3

Give this a try:
Sub dotKiller()
For Each cell In Intersect(Range("P:P"), ActiveSheet.UsedRange)
v = cell.Text
If InStr(v, ".") > 0 Then
cell.Clear
cell.NumberFormat = "#"
cell.Value = Replace(v, ".", "")
End If
Next cell
End Sub
If the cell does not contain a dot it will not be changed.
Before:
and after:

Answer 4

Try this
Sub Test()
Columns("P:P").Replace What:=Application.DecimalSeparator, Replacement:="", LookAt:=xlPart, MatchCase:=False
End Sub
Or manually File >> Options >> Advanced >> Uncheck (Use system separators)