Excel button that shows the elements of the previous row - excel

Question

I used the code from https://stackoverflow.com/a/34454648/11447549
I got it to use dynamic column length and take values from a cell in another sheet. This code currently gives me the element of the next row(i.e., A1 -> click -> A2) and then if the last element, it returns to the first one.
Know I need this to go backward. It needs to go from bottom to up and if it hits the first one, go to the last one. I tried my reversing the parameters of Rangebut got an error.
Any ideas or hints will be very useful.
Sub Button8_Click()
Set wsh = ActiveWorkbook.Worksheets("Sheet1")
Column = wsh.Range("A" & Rows.Count).End(xlUp).Row
If IsError(Application.Match(Range("B2").Value, wsh.Range(wsh.Cells(2, 1), wsh.Cells(Column, 1)), 0)) Then
Range("B2").Value = wsh.Cells(2, 1).Value
ElseIf Application.Match(Range("B2").Value, wsh.Range(wsh.Cells(2, 1), wsh.Cells(Column, 1)), 0) = wsh.Range(wsh.Cells(2, 1), wsh.Cells(Column, 1)).Cells.Count Then
Range("B2").Value = wsh.Cells(2, 1).Value
Else
Range("B2").Value = wsh.Cells(2, 1).Offset(Application.Match(Range("B2").Value, wsh.Range(wsh.Cells(2, 1), wsh.Cells(Column, 1)), 0), 0).Value
End If
End Sub

Answer 1

If you are absolutely certain there are no duplicates, you can use the Range.Find method, which is a built-in VBA function.
Option Explicit
Private Sub CommandButton1_Click()
Dim rDest As Range, rCol As Range, C As Range
Dim wsSrc As Worksheet
Dim myRow As Long, LR As Long
Set wsSrc = Worksheets("sheet2") 'or whatever
With wsSrc
Set rCol = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
End With
Set rDest = Cells(2, 2)
With rCol
Set C = .Find(what:=rDest, after:=rCol(1, 1), LookIn:=xlValues, _
lookat:=xlWhole, searchorder:=xlByRows, searchdirection:=xlPrevious)
If Not C Is Nothing Then
If C.Row = 1 Then Set C = rCol(rCol.Rows.Count + 1, 1)
rDest = C.Offset(-1, 0)
Else
rDest = rCol(rCol.Rows.Count, 1)
End If
End With
End Sub

Answer 2

I find your code cumbersome (or perhaps not complicated enough :-)). Here is another version. It works on double-click on A1. It needs to be installed in the code sheet of the worksheet on which you want the action.
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Const Rstart As Long = 2 ' set as required
Dim Rng As Range
Dim Rcount As Long
Dim R As Variant
With Target
If .Address = Range("A1").Address Then
' from Rstart to last row in column B
Set Rng = Range(Cells(Rstart, "B"), Cells(Rows.Count, "B").End(xlUp))
Rcount = Rng.Cells.Count
On Error Resume Next
R = Application.Match(.Value, Rng, 0)
If Err Then
R = Rcount
Else
R = R + 1
If R > Rcount Then R = 1
End If
.Value = Rng.Cells(R).Value
.Offset(1).Select
End If
End With
End Sub
Once you understand the code it is both easier to read and to modify. For example, to change the cell A1, all you need to do is to change the reference to A1 in this line of code. If .Address = Range("A1").Address.
Your list of choices need not start in row 1. Const Rstart now has a value of 2, meaning your list starts in row 2, allowing for a column caption, but you can change it to 1, if you prefer, or 3.
The line of code Set Rng = Range(Cells(Rstart, "B"), Cells(Rows.Count, "B").End(xlUp)) sets the range of your list to column B. Change the two "B"s to move it to another column. It finds the end dynamically. The beginning is taken from the setting of Rstart.
Finally, there is no button. But if you prefer a button to double-click it will be easy to adapt the code to the use of one.
What would be the good of "finally" if there weren't one more word to say. This code can easily be adapted to have different triggers referring to different lists on the same sheet. For example, you could move the list now in column B to be below A1. In column B you could have another list that responds to a double-click in B1 etc.