Delete rows based on more than one condition - excel

Question

can you help me with the following code I made?
Sub DeleteRows()
Dim c As Range
Dim SrchRng
Set SrchRng = ActiveSheet.Range("A1", ActiveSheet.Range("A65536").End(xlUp))
Do
Set c = SrchRng.Find("12345", LookIn:=xlValues)
If Not c Is Nothing Then c.EntireRow.Delete
Loop While Not c Is Nothing
End Sub
I have a chart with program codes in column A. I want to create a macro that will delete all rows with specific program codes: 12345, 541, 9099, etc.
The code I have can only refer to one value. I don't know how to add more. And on top of that, it will delete program codes with "12345" in it. For example, it will delete rows with the program code: 123456. Can we prevent it from doing that too?
P.S. not sure if it's a good idea to set the range like I did: A1:A65536. too big?
Thank you!

Answer 1

You should instead iterate over the range. You also don't want to set the range that large if you don't have that much data.
Sub DeleteRows()
Dim i As Long
Dim last_row As Long
last_row = ActiveSheet.Range("A65536").End(xlUp).Row
For i = last_row To 1 Step -1
If ActiveSheet.Cells(i, 1).Value = "12345" or _
ActiveSheet.Cells(i, 1).Value = "541" or _
ActiveSheet.Cells(i, 1).Value = "9099" Then
ActiveSheet.Cells(i, 1).EntireRow.Delete
End If
Next i
End Sub

Answer 2

This way you can go over the values inside the array with the values/strings you want to check inside the data:
Sub DeleteRows()
Dim c As Range
Dim i
Dim r
Dim theValues(1 To 5)
Dim SrchRng As Range
theValues(1) = "1231"
theValues(2) = "1232"
theValues(3) = "1233"
theValues(4) = "1234"
theValues(5) = "1235"
r = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
Set SrchRng = Range(Cells(1, 1), Cells(r, 1))
For Each i In theValues
Do
Set c = SrchRng.Find(i, LookIn:=xlValues, LookAt:=xlWhole)
'see the ", LookAt:=xlWhole" added, this way you can find just the Whole values.
If Not c Is Nothing Then c.EntireRow.Delete
Loop While Not c Is Nothing
Next i
End Sub
Edit #1
As you ask in the comments, see the edit to: go over the data looking just for the complete values (you look for 91 not 910 or 1891), then heres is my version if you want to put the values inside a range in a sheet, then you can add any value to be found.
Sub DeleteRows()
Dim c As Range
Dim i
Dim r
Dim rng As Range
Dim a
Dim theValues()
Dim SrchRng As Range
r = Range("T1").End(xlDown).Row
Set rng = Range("T1", Cells(r, 20))
For a = 1 To rng.Count 'in this range i store the values
ReDim Preserve theValues(1 To a)
theValues(a) = rng(a)
Next a
r = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
Set SrchRng = Range(Cells(1, 1), Cells(r, 1))
For Each i In theValues
Do
Set c = SrchRng.Find(i, LookIn:=xlFormulas, LookAt:=xlWhole)
If Not c Is Nothing Then c.EntireRow.Delete
Loop While Not c Is Nothing
Next i
End Sub