Why does my Excel VBA code not fully execute on first attempt? - excel

Question

To start, I am using Excel 2016 on Windows 10.
I have a spreadsheet in Excel that utilizes two macros to either insert data based on a userform or delete all data from the spreadsheet when someone wants to clear it. The focus of this question is the program that clears the data (seen below), though I will be discussing the other one as well.
Sub ClearData()
ToDelete = MsgBox("Are you sure you want to delete all data?", vbYesNo, "Are you sure?")
if ToDelete = vbYes Then
ActiveSheet.Unprotect "Password"
Do While Range("A2").Value <> ""
Range("A2:J2").Delete Shift:=xlUp
Loop
ActiveSheet.Protect "Password"
End If
End Sub
The code is pretty straight forward. It asks the user to confirm they want to delete all the data, and if they do, it unlocks the sheet, continuously deletes the second row until there are no more rows, and then it locks the sheet back.
Problem: So let's say I have 10 rows of data in my spreadsheet and hit the button that leads to the ClearData() sub. In this case, the first row deletes, and then the macro stops entirely, leaving 9 rows of data. Now if I hit the ClearData() button again, the macro executes flawlessly and deletes the remaining 9 rows.
I thought maybe the issue was with the locking and unlocking the spreadsheet portion of the code. So I manually unlocked the sheet and clicked the button, and the same bug occurred.
Another similar issue that occasionally occurs with the "insert data" macro is that it will only add data to one cell (not even a full row, just the first cell). Then, if I run the program again and enter the same exact information into the userform, all of it fills in correctly. In both of these cases, the macro runs through a few lines of code until it executes the first line of code that actually updates the spreadsheet and then completely exits the code without executing any further lines. Also note that no error messages occur, either.
One thing to note is that this problem appears to be intermittent. I just tried it again, and the data is filling out and clearing correctly. There is one thing I can do that will cause the "insert data" macro to have the problem. If I change the code and save it again, even if the code I changed was irrelevant (e.g. adding a space to a comment), then the insert data error will occur on the next execution.

Answer 1

Not an actual answer to your question, but a suggestion to help debuging it.
Add a trap to detect the error condition, and break into debug mode, so you can examine the state of things.
Sub ClearData()
Dim ToDelete As VbMsgBoxResult
Dim RowCount As Long
ToDelete = MsgBox("Are you sure you want to delete all data?", vbYesNo, "Are you sure?")
If ToDelete = vbYes Then
ActiveSheet.Unprotect "Password"
Do While Range("A2").Value <> ""
Range("A2:J2").Delete Shift:=xlUp
RowCount = RowCount + 1
Loop
If RowCount = 1 Then Stop
ActiveSheet.Protect "Password"
End If
End Sub
It the loop ends after one deletion, the code will break on the Stop command. You can then examine the state of your sheet and the value of cell A2, which may (or may not!) shed some light.
Again not an answer, but an alternative method:
This assumes two things
- There is no additional data you want to keep below the first blank row in column A
- There is no additional data you want to keep to the right of column J
If either of these assumptions are wrong, the code can easily be adjusted to suit
Sub ClearData()
Dim rng As Range
If MsgBox("Are you sure you want to delete all data?", vbYesNo, "Are you sure?") <> vbYes Then Exit Sub
With ActiveSheet
Set rng = .Range(.Cells(.Rows.Count, 1).End(xlUp), .Cells(2, 1))
' account for possibility there are no data rows
If rng.Row = 1 Then Exit Sub
.Unprotect "Password"
rng.EntireRow.Delete
.Protect "Password"
End With
End Sub