Range function sending data to wrong row - excel

Question

I'm trying to add data to a worksheet, and while I know I've set up the Range function "correctly" (for a value of correctly that includes "worked every other time"), instead of labeling row 1 it's labeling row 2, and shifting the calculations in row 2 down to row 3. This is a problem only with this module in this worksheet.
I've tried the debugging tools, but they don't change the outcome or break anywhere. The first row hidden, nor is it frozen. And this happens whether or not I append ".value" after the range calls.
Weirdly, the second set of labels and calculations (starting at "With Calcs.UsedRange") are ending up in the correct cells. Code below:
Sub CalcGDD()
'Initialize
Dim nb As Workbook
Dim Clim, Vars, CC, Calc As Worksheet
Dim LRow, RowL As Long
'Setup
Set nb = ActiveWorkbook
Application.ScreenUpdating = False
Set Vars = nb.Sheets("Variables")
Set CC = nb.Sheets("CoverCrop")
Set Calcs = nb.Sheets("Summary")
Set Clim = nb.Sheets("Climate")
'Calculations in Climate Sheet
With Clim.UsedRange
LRow = Cells(Rows.Count, "A").End(xlUp).Row
.Range("H1") = "Plant Day"
.Range("I1") = "Harv Day"
.Range("J1") = "Fall GDDs"
.Range("K1") = "Spring GDDs"
.Range("H2:H" & LRow & "").FormulaR1C1 = (...calculations elided...)
End With
'Summarize
RowL = CC.Cells(Rows.Count, "A").End(xlUp).Row
With Calcs.UsedRange
.Range("A1") = "Year"
.Range("B1") = "Fall GDD"
.Range("C1") = "Spring GDD"
.Range("D1") = "Total GDD"
.Range("A2:A" & RowL & "").FormulaR1C1 = (...calculations elided...)
End With
End Sub
Any ideas why Range("H1") is printing to H2? Thanks much.

Answer 1

The .UsedRange is likely offsetting your addressing. Remove it in both With statements. If the UsedRange starts in row 2, then "A1" in that range refers to the top-left cell in that range. If you want to write to absolute cell address A1 (i.e. not relative to where UsedRange starts), work off the actual worksheet cells instead.
'Calculations in Climate Sheet
With Clim.UsedRange
LRow = Cells(Rows.Count, "A").End(xlUp).Row
That Cells call is implicitly going against whatever the ActiveSheet happens to be. Qualify it with the Worksheet object you mean to work with - in this case, most likely the With block variable:
'Calculations in Climate Sheet
With Clim
LRow = .Cells(Rows.Count, "A").End(xlUp).Row
See if Rubberduck (free, open-source VBIDE add-in project I manage) can spot more implicit ActiveSheet references (and other potential issues in your code, like these implicit Variant variables:
Dim Clim, Vars, CC, Calc As Worksheet
Dim LRow, RowL As Long
Also:
And this happens whether or not I append ".value" after the range calls
That's because the .Value member call is implicit if it's not specified.