How do you multiply 2 dimmed ranges using vba - excel-formula

Question

I am trying to create a macro to import 30 random numbers, and multiply each one by a predefined population.
I can't use fixed ranges as the range will be different for each use.
I have got it all working, except for the multiplication part - I can't get that line of code to compile.
Dim N As Integer '(counter)
Dim rng As Range '(activecell address)
Dim rand As String '(convert address to string)
Dim pop As Range '(population address - absolute reference)
Dim pop1 As String '(population address as string)
N = 0
ActiveCell.Formula = "Population:"
ActiveCell.Offset(0, 1).Select '(select cell next to population)
Set pop = ActiveCell '(create absolute reference point)
pop1 = pop.Address '(convert to string)
ActiveCell.Offset(2, -1).Select '(move to starting point for random)
Do Until N = 30
N = N + 1 '(count for loop)
ActiveCell.FormulaR1C1 = "=ROUNDUP(RAND(),4)" '(random formula)
ActiveCell.Copy
ActiveCell.PasteSpecial xlPasteValues
Set rng = ActiveCell '(set address for multiplication)
rand = rng '(convert address to string)
ActiveCell.Offset(0, 1).Select '(move to next column to multiply)
ActiveCell.FormulaR1C1 = "=" & pop & "*" & rng" '(ERROR)
ActiveCell.Offset(1, -1).Select
Loop
ActiveCell.Offset(-1, 0).Select
If I start at A1 and press the macro, I expect B3 to have the following formula in it:
=$A$3*$B$1
and for this to be repeated up until B33.

Answer 1

Either of the two procedures below will populate your range, although I can't figure out how you're picking your range (so have hard-coded the ranges in).
The first uses an array formula:
Sub Test()
Dim rng As Range
Dim multiplier As Range
Set rng = ThisWorkbook.Worksheets("Sheet1").Range("B4:B7")
Set multiplier = ThisWorkbook.Worksheets("Sheet1").Range("B2")
rng.Offset(, 1).FormulaArray = "=" & rng.Address & "*" & multiplier
End Sub
This method uses separate formula for each row:
Sub Test1()
Dim rng As Range
Dim multiplier As Range
Dim cell As Range
Set rng = ThisWorkbook.Worksheets("Sheet1").Range("B4:B7")
Set multiplier = ThisWorkbook.Worksheets("Sheet1").Range("B2")
rng.Offset(, 1).Resize(1).Formula = "=" & rng.Resize(1).Address(RowAbsolute:=False) & "*" & multiplier
rng.Offset(, 1).FillDown
End Sub
Following on from your comment below you could use:
Sub Test1()
Dim rng As Range
Dim multiplier As Range
Dim cell As Range
Set cell = ActiveCell 'Grab the ActiveCell reference.
cell = "Population:"
'2 cells down from the ActiveCell and resized to 30 cells.
With cell.Offset(2).Resize(30)
'Add random values and remove the formula.
.Formula = "=ROUNDUP(RAND(),4)"
.Value = .Value
'Add the multiplication formula and fill down.
.Offset(, 1).Resize(1).Formula = _
"=" & .Resize(1).Address(RowAbsolute:=False) & "*" & cell.Offset(, 1).Address
.Offset(, 1).FillDown
End With
End Sub
Further reading: FillDown, Resize & With...End With