VBA - running an excel macro take forever - excel

Question

I am running this macro and its either taking forever or something is wrong with the way I wrote it. I am new to Excel Macros, and I can't seem to figure out how to write this better that it won't crash my PC.
Sub Test()
ScreenUpdating = True
Dim maxRows As Integer
maxRows = 2332
For i = maxRows To 2 Step -1
'if the cell is empty, delete the row
'otherwise delete the first cell of the row and shift over
If Cells(i, 2).Value = "" Then
Rows(i).Delete
Else
Cells(i, 1).Delete
End If
Next i
ScreenUpdating = False
End Sub

Answer 1

In general, whenever delete is used, it is a good idea to do it only once, for all the cases. However, in the case of the OP, there are two cases separately - deleting a whole row and deleting only one cell. Thus, the delete method could be used twice:
Sub TestMe()
Dim maxRows As Long: maxRows = 2332
Dim myRangeRows As Range
Dim myRangeCells As Range
Dim i As Long
For i = maxRows To 2 Step -1
With Worksheets(1)
If .Cells(i, 2) = "" Then
If myRangeRows Is Nothing Then
Set myRangeRows = .Rows(i)
Else
Set myRangeRows = Union(.Rows(i), myRangeRows)
End If
Else
If myRangeCells Is Nothing Then
Set myRangeCells = .Cells(i, 1)
Else
Set myRangeCells = Union(.Cells(i, 1), myRangeCells)
End If
End If
End With
Next i
If Not myRangeRows Is Nothing Then myRangeRows.Delete
If Not myRangeCells Is Nothing Then myRangeCells.Delete
End Sub
Additionally, whenever the cell in Excel is referred like this Cells(i, 2).Value, then the referring is either to the ActiveSheet or to the Worksheet in which the code resides. Thus, it is a good practice to explicitly mention the worksheet, like in this case:
With Worksheets(1)
If .Cells(i, 2) = "" Then