How to textbox checks itself - excel

Question

I am trying to do textboxes which would be validating input (for numbers only).
I am still new to classes and am little bit confused about some things, but trying my best to learn.
I have multiple textboxes in userform and want to every one of them to be numeric input only.
For the begining I started to check just one textbox (vzdalenost1).
First code just to create connection between textbox and class
Dim chk As New Class1
Private Sub UserForm_Initialize()
Set chk.ChkEvents = Controls("Vzdalenost1")
End Sub
Second code is actual class module
Option Explicit
Public WithEvents ChkEvents As MSForms.TextBox
Private Sub ChkEvents_change()
If IsNumeric(Me.Value) Or Me.Value = "" Then
Else
MsgBox "blablabla"
Me.Value = ""
End If
End Sub
When I try to write something into textbox "vzdalenost1" excel shows error message "Method or data member not found"..
I have even something like replacing "me.value" for "me.control.value" which didnt work either..

Answer 1

The keyword Me in this context refers to the class object itself, not the textbox. Use ChkEvents to refer to the textbox - ChkEvents.Value.
Here's how you could re-write your code to deal with multiple textboxes. First, let's give your class a meaningful name, let's call it clsTextbox. Then, in keeping with the principle of encapsulation, let's declare the object in your class as Private, instead of Public. This will prevent the public from having direct access to it. Instead, we'll use a member function to assign a textbox to a class object. So the code for our class module would look like something this...
Option Explicit
Private WithEvents tb As MSForms.TextBox
Private Sub tb_Change()
MsgBox tb.Name
End Sub
Public Function SetTextbox(ByRef obj As MSForms.TextBox)
Set tb = obj
End Function
Then, for our userform, first we declare a collection at the module level to hold our class objects. Then, since we will be creating multiple class objects, we declare a class object without the keyword New. Instead, we'll use that keyword each time we create a new object, and then we'll add that new object to our collection. So the code for our userform would look something like this...
Option Explicit
Dim textboxCollection As Collection
Private Sub UserForm_Initialize()
Set textboxCollection = New Collection
Dim cTextbox As clsTextbox
Dim ctrl As MSForms.Control
For Each ctrl In Me.Controls
If TypeName(ctrl) = "TextBox" Then
Set cTextbox = New clsTextbox
cTextbox.SetTextbox ctrl
textboxCollection.Add cTextbox
End If
Next ctrl
End Sub

Answer 2

If I get your question correctly you want a textbox to accept only numbers, correct?
In that case try this:
Private Sub TextboxName_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
char = Chr(KeyAscii)
KeyAscii = Asc(UCase(char))
Debug.Print KeyAscii
If KeyAscii >= 48 And KeyAscii <= 57 Then
Debug.Print "number"
Else
Debug.Print "other"
KeyAscii = 0
End If
End Sub
Just replace TextboxName in the Sub name with whatever name you have and it should work.