Speeding up macro that goes through a workbook overwriting sheets by value - excel

Question

I made an Excel VBA macro that goes through a workbook sheet by sheet and if the sheet contains no pivots it will overwrite it by value. Unfortunately, on at least one workbook it takes so long that I can go through each sheet myself faster. I am wondering what to do to speed it up. Can anyone suggest what I need to do to accomplish this?
' Convert entire workbook's worksheets to values
'
Sub workbook_overrideSheetsToValues_noSave()
Dim answer As Long, c As Long, ws As Worksheet, report As String
answer = MsgBox("Overwrite formulas in this workbook?", vbYesNo + vbQuestion, "Warning! Formula overwrite!")
If answer = vbNo Then Exit Sub
For Each ws In Worksheets
' only copy over by value if there aren't any pivot tables in the sheet.
If ws.PivotTables.count = 0 Then
Call copySheetByValue(ws.Name)
' save all sheets being skipped
Else
c = c + 1
report = report & Chr(10) & c & ". " & ws.Name
End If
Next ws
If report <> "" Then Call MsgBox("Sheets with pivots were skipped:" & report, 0, "Warning!")
End Sub
Sub copySheetByValue(sheetName As Variant, Optional cellPos As String = "A1")
Dim vFlag As Boolean
' Handle case where sheet is hidden
If sheets(sheetName).Visible = False Then
sheets(sheetName).Visible = True
vFlag = True
End If
Worksheets(sheetName).Unprotect
On Error Resume Next
Worksheets(sheetName).ShowAllData ' Clear filters on all columns
Worksheets(sheetName).Cells.EntireColumn.Hidden = False ' Unhide all columns
On Error GoTo 0
Worksheets(sheetName).Cells.Copy
Worksheets(sheetName).Cells.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Application.CutCopyMode = False
Application.Goto Worksheets(sheetName).Range(cellPos)
' Hide sheet if it was unhidden above
If vFlag = True Then
sheets(sheetName).Visible = False
vFlag = False
End If
End Sub
The workbook where it works really slowly has 27 worksheets with 12 containing pivots. The 15 remaining each have under 1000 rows with the exception of one containing 24000. Doing a Ctrl-A, Ctrl-C and then pasting by value only takes a moment when done manually.

Answer 1

Ben,
First thing would be to add a few controls to make sure Excel isn't allowed to calculated things:
Application.ScreenUpdating=False
Application.Calculation = xlCalculationManual 'xlCalculationAutomatic to revert back
Application.EnableEvents = False
Application.DisplayAlerts = False
Application.DisplayStatusBar = False
Application.StatusBar = False
Then, you did a great thing using Worksheets(sheetName) to make sure your code really execute on the good worksheet but you should really encapsulate it in a With block to avoid the code to evaluate what this Worksheet object is:
With Worksheets(sheetName)
' Handle case where sheet is hidden
If .Visible = False Then
.Visible = True
vFlag = True
....
' Hide sheet if it was unhidden above
If vFlag = True Then
.Visible = False
vFlag = False
End If
End with
Finally, think about writing the value to your cell instead of doing a copy-paste, because copy-paste is really slow. Think about limiting your macro to the range your worksheet really use.
'Supposing your data start at A1
Dim EndRow As Long
Dim EndColumn As Long
With Worksheets(sheetName)
EndRow = .Range("A" & .Rows.Count).End(xlUp).Row
EndColumn = .Cells(1, .Columns.Count).End(xlToLeft).Column
.Range(.Cells(1, 1), .Cells(EndColumn, EndColumn)).Value2 = .Range(.Cells(1, 1), .Cells(EndColumn, EndColumn)).Value2
End With