Splitting delimitted column using ONLY formula - excel

Question

There are similar requests, but not quite what i'm after. Take this example value:
aa;bb;cc;dd
The values between each semi-colon aren't fixed. They range from 3-15 characters. I need to pull the substring out from between the semi-colons.
I've got 'aa' and 'bb' sorted, but i'm struggling with 'cc' onwards. Here are my first two formulae:
=LEFT(A1,FIND(";",A1)-1)
...get values to the left of the first semi-colon
=MID(A1,
(FIND(";",A1)+1),
FIND(";", A1, (FIND(";",A1) + 1))-(FIND(";", A1) + 1))
...get values between the first and second semi-colon. Stuck at the third (wish I could use variables.. JSON perhaps?)
The end goal is to split out a multi-choice column into 5 columns for Power BI reporting. We want all of the computation done and dusted before it hits the report; I know there is a split on delimiter option in Power BI.
Any assistance would be much appreciated, thanks.
P.S. Tagged in Excel since Sharepoint apparently uses the same formulas, and that's what i'm testing in at the moment.

Answer 1

I can't assure you to work it in sharepoint but it will work on excel. Try below formula.
=TRIM(RIGHT(LEFT(SUBSTITUTE($A1,";",REPT(" ",100)),COLUMNS($A$1:A1)*100),100))
As per below screenshot, put the formula in B1 cell then drag to right as needed.

Answer 2

There are dozens of ways of doing it just with formulas. Without going to anything too esoteric and without resorting to array formulas you could use something like:
=TRIM(MID(SUBSTITUTE($A3,";",REPT(" ",LEN($A3))),(COLUMN(F:F)-2)*LEN($A3)+1,LEN($A3)))

Answer 3

Try this:
Create a header row where your fields will be split out to, numbered from 1 to 5 (in cells B1 - F1). These #s will be used in the formula.
The 2nd row will have the start of your data (in cell A2). In cell B2, enter this formula:
=TRIM(MID(SUBSTITUTE($A2,";",REPT(" ",LEN($A2))),(B$1-1)*LEN($A2)+1,LEN($A2)))
Then you can use the fill handle (+) to copy it across from B2 to F2.
Reference: https://exceljet.net/formula/split-text-with-delimiter
Beautified version of the formula:
=TRIM(
MID(
SUBSTITUTE(
$A2,
";",
REPT(
" ",
LEN(
$A2
)
)
),
( B$1 - 1 ) *
LEN(
$A2
) + 1,
LEN(
$A2
)
)
)
And for 1-time interactive passes, you can use Excel's built-in delimiting: Go to Data -> Text to Columns and walk through the wizard.