Remove the commas, spaces and "NULL" string to 0(Zero) from Column - excel

Question

I am newbie to Excel VBA.
Need help to removing the commas, spaces and NULL string to "0" from ColumnName called StringName.
First, I have tried to remove the commas, spaces from the ColumnName called StringName and finally to find and replace the "NULL" string to 0(Zero).
Here is the code to Replace for commas, spaces from the ColumnName called StringName.
Sub ReplaceCharacters()
Application.ScreenUpdating = False
Dim lrow As Long
lrow = Cells(Cells.Rows.Count, "A").End(xlUp).Row
With ActiveSheet.Range("A2:A" & lrow).SpecialCells(xlCellTypeConstants, xlTextValues).Cells
.Replace What:=",", Replacement:="", LookAt:=xlPart
.Replace What:=" ", Replacement:="", LookAt:=xlPart
End With
Application.ScreenUpdating = True
End Sub
I am struggling to find and Replace the string "NULL" to 0 from the ColumnName called StringName.
I need help with this and I have tried a lot and ended up here for a solution.
Here is what I have tried..
' not working
Sub UpdateWhole()
With ActiveSheet.UsedRange
.Replace "NULL", "0", xlWhole
End With
End Sub
' not working
Sub FormulaRng()
For i = 2 To 10
Worksheets("Sheet1").Range("A2:A" & i).FormulaR1C1 = "=IF(A" & i & "=""NULL"",0,A" & i & ")"
Next
End Sub
Thanks in Advance
Here is the sample data to test
StringName
------------------
NULL
NULL
null
nullasdf
cbgrgNULLdf343
, asdfwe 4fdt
456fg , d55nullNULL
sdf34 df, 4fd
NULLfgf null
121
22
34545
Required OutPut
------------------------
0
0
0
nullasdf
cbgrgNULLdf343
asdfwe4fdt
456fgd55nullNULL
sdf34df4fd
NULLfgfnull
121
22
34545

Answer 1

The following revised procedure should work for you. I used the Clean function to remove all non-printable characters from the text before replacing the NULL text with 0.
VBA Code
Public Sub ReplaceCharacters()
On Error GoTo ErrTrap
Const ProcedureName As String = "ReplaceCharacters"
Dim sheet As Worksheet: Set sheet = ActiveSheet
Dim cell As Range
Application.ScreenUpdating = False
For Each cell In sheet.UsedRange.Cells
cell = Trim(Application.WorksheetFunction.Clean(cell))
cell.Replace What:="NULL", Replacement:=0, LookAt:=xlWhole
cell.Replace What:=",", Replacement:="", LookAt:=xlPart
cell.Replace What:=" ", Replacement:="", LookAt:=xlPart
Next cell
ExitProcedure:
On Error Resume Next
Application.ScreenUpdating = True
Set sheet = Nothing
Exit Sub
ErrTrap:
Select Case Err.number
Case Else
Debug.Print "Procedure: " & ProcedureName & " |Error #: " & Err.number & " |Error Description: " & Err.description
End Select
Resume ExitProcedure
Resume 'for debugging
End Sub
Example Video

Answer 2

Try this.
Sub test()
Dim Ws As Worksheet
Dim rngDB As Range
Set Ws = ActiveSheet
With Ws
Set rngDB = .Range("a2", .Range("a" & Rows.Count).End(xlUp))
End With
With rngDB
.Replace What:=",", Replacement:="", LookAt:=xlPart
.Replace What:=" ", Replacement:="", LookAt:=xlPart
.Replace What:="NULL", Replacement:="0", LookAt:=xlWhole
.Replace What:="null", Replacement:="0", LookAt:=xlWhole
End With
End Sub