I'm a novice to Excel. I don't which formula to use. I want to set up a budget for 12 months, that quite easy ex. 12000/12= 1000 in 12 columns. I need a formula for when one column answer is changed by hand lets say to 2000, that will the remaining columns answers automatically change to 909.09. I don't which formula to use and if its do able?
Thanks for your help
Kind regards
Johan
You could add a helper column in which you keep track of the manually entered values.
Let's say the Total value (12000) is in A1, months are in column A2:A13 and the helper column is column C.
Column B would then be;
=IF(C2<>"",C2,(A$1-SUM(C$2:C$13))/(12-COUNT(C$2:C$13)) for cell B2, simply extend to the other cells in column B
Related
I hope I can explain sufficiently for someone to understand and be able to help, I have 27000 records to update into one column.
I'm hoping to use a formula to fill column D with data from column A but if that cell is blank use data from column B and again if that column is blank use data column c.
]: https://i.stack.imgur.com/DTwI7.png
Try this:
=IF(A1<>"",A1, IF(B1<>"",B1,IF(C1="","",C1)))
This doesn't use IF, and so is more flexible for use with longer ranges.
=INDEX(FILTER(A1:C1,A1:C1>"",""),1)
It FILTERs the row for non-empty text cells, and returns the first one via INDEX.
May be like this in your cell D2
=IF(A2<>"", A2, IF(A2="", B2, Value(C2)))
I have searched high and low on the internet and still can't find a solution to what seems to be a simple issue so I am here hoping someone will enlighten me.
I have a table(not pivot) in Excel 2010 and I need a formula that will calculate the average of a group of cells in column B based on the date in column A and display it in column C but only on the first line of the date(s).
Columns A and B are static. Only column C needs a formula.
Thanks in advance for any ideas.
Here is what I want the table to look like when calculated:
Solution 1 - using a helper pivot table
You can first use the data in Column A and B to make a pivot table such as the following, suppose the pivot table is located in Column F and G, change the value field settings of Sys to summarise the value filed by Average :
Then in cell C3, enter the following formula and drag it down:
=IF(A3=A2,"",VLOOKUP(A3,F:G,2,0))
Solution 2 - using array formula
In cell A3, enter the following formula and then press Ctrl+Shift+Enter upon finish, then drag the formula down:
=IF(A3=A2,"",AVERAGE(IFERROR(List_Sys/(List_Date=A3),"")))
Find attached :D I used Averageif function, and if to verify if any change in date. then just scrolled down.
Screenshot:
Try following formula-
=IF(COUNTIF($A$3:$A3,A3)=1,AVERAGEIF($A$3:$A$19,A3,$B$3:$B$19),"")
I have the following scenario.
Driving Toyota Hilux Best
Driving Mitsubishi Triton
Driving Ford Ranger Good
Driving Hilux Best
Driving Ranger Good
I would like to use a formula to automatically rearrange the upper table to the lower table.
I was actually trying to eliminate all rows with empty cell in fourth column and then remove the second column.
What formula should I use ?
Thank you.
In A6, copied across and down :
=IFERROR(INDEX($A:$D,MMULT(SMALL(($D$1:$D$3="")/1%%+ROW($1:$3),ROWS($1:1)),1),INDEX({1,3,4},COLUMN(A1)))&"","")
As per below screenshot use following formula to A6 cell.
=IFERROR(INDEX($A$1:$D$3,AGGREGATE(15,6,ROW($1:$3)/($D$1:$D$3<>""),ROW(1:1)),1),"")
You need to change Column reference of INDEX() formula for 2nd and 3rd column as you want to skip B Column. So, for cell B6 formula will be...
=IFERROR(INDEX($A$1:$D$3,AGGREGATE(15,6,ROW($1:$3)/($D$1:$D$3<>""),ROW(1:1)),3),"")
If you notice Column argument is 3 here because we skip column 2 of your source data.
My question is relatively simple I believe, just not getting it just yet. So here is where I am having trouble,
Let's say, Column C has numbers from C3:C33, I have other items underneath C33 but want to have a SUM of C3:C33 in Column J4 as total. That is easy enough, but when I try inserting a line at C33 to add an additional number, it doesn't automatically SUM in the cell J4. I've looked for answers and I've came across this formula:
=SUM(INDIRECT("C3:C"&ROW()-1))
That works right under C33, and works fine if I have J4 =C33 and just simply hide that formula's row. But I'm wondering is there another Formula that will automatically auto adjust SUM from J4?
Any help would be great!
-Maykid
Use:
=SUM(C3:INDEX(C:C,MATCH("Totals",A:A,0)-1))
Now no matter the number of rows, it will sum only those from C3 to the row above where Totals is found in column A.
Try to use SUM(C3:C34) and leave C34 blank. You should now be able to insert below C33 and the formula should automatically adjust.
I have a spreadsheet for expenses that I want to be able to apply a formula to the Subtotal column if the currency is JMD. Else, I want to leave sum unchanged. Here is an row that I want to apply to. I only will have one value in one of the columns.
I need the subtotal column to take the column in the row that has a value, if it is JMD, then I need to multiply the value times ".0089" for converting to USD. If the value is USD, then I need to put the value as is in the subtotal column.
Any help greatly appreciated!
I recommend adding a column in which you choose USD or JMD ideally from a drop down (see data validation). If you add it to the left of the current column C, the formula could be as follows:
=sum(F9:M9)*IF(C9="USD",1,0.0089)
Simple, explicit and easy to maintain!
You may have other conditions that you might want to account for down the road, but the following formula addresses your question as is:
Enter the following in cell M9 and copy down as needed:
=IF(IFERROR(MATCH("*USD*",E9:L9,0),0)<>0,TEXT(SUBSTITUTE(INDEX(E9:L9,MATCH("*USD*",E9:L9,0)),"USD ",""),"0.00"),IF(IFERROR(MATCH("*JMD*",E9:L9,0),0)=0,"",TEXT(SUBSTITUTE(INDEX(E9:L9,MATCH("*JMD*",E9:L9,0)),"JMD ","")*0.0089,"0.00")))
Hope this helps. Cheers!