Sorting a hasheq list in Racket - hashmap

Question

I am creating a function 'sort-mail' in Racket, that takes in a list of hash-eq s and sorts them based on their Data key. The input is defined this way:
(define test-dates
'("Sun, 10 Sep 2017 09:48:44 +0200"
"Wed, 13 Sep 2017 17:51:05 +0000"
"Sun, 10 Sep 2017 13:16:19 +0200"
"Tue, 17 Nov 2009 18:21:38 -0500"
"Wed, 13 Sep 2017 10:40:47 -0700"
"Thu, 14 Sep 2017 12:03:35 -0700"
"Wed, 18 Nov 2009 02:22:12 -0800"
"Sat, 09 Sep 2017 13:40:18 -0700"
"Tue, 26 Oct 2010 15:11:06 +0200"
"Tue, 17 Nov 2009 18:04:31 -0800"
"Mon, 17 Oct 2011 04:15:12 +0000"
"Sun, 16 Oct 2011 23:12:02 -0500"
"Mon, 11 Sep 2017 14:41:12 +0100"))
(define test-hashes (map (lambda (x) (hasheq 'Date x)) test-dates))
I have tried following the answer to this question, but I don't think it's what I'm looking for. So far, I am trying to sort them using the following:
(define (sort-mail test-hashes)
(sort test-hashes #:key car <))
Unfortunately, I am getting this error:
car:contract violation
expected: pair?
given: 'hasheq((Data . "Wed, 13 Sept 2017 17:51:05 +0000"
I'm pretty confused as to what my sort statement should look like, so any guidance would be great. Thank you!

Answer 1

There are two problems.
First, the reason for the error message is that sort calls car (the #:key function) on each element of the test-hashes list, and each of those elements is a hash-table, not a list. car expects a list, hence the error.
Your #:key function needs to extract the date from the hash table. hash-ref does that. So here's a first attempt at sort-mail:
(define (sort-mail hash-tables)
(define (date-of ht) (hash-ref ht 'Date))
(sort hash-tables #:key date-of string<?))
This brings us to the second problem, which is the function for comparing dates. Notice that the comparison function above is string<? rather than <. That's because the value associated the Date key in each hash table is a string. Calling string<? avoids a run-time type error, but the dates get sorted in the wrong order:
> (sort-mail test-hashes)
'(#hasheq((Date . "Mon, 11 Sep 2017 14:41:12 +0100"))
#hasheq((Date . "Mon, 17 Oct 2011 04:15:12 +0000"))
#hasheq((Date . "Sat, 09 Sep 2017 13:40:18 -0700"))
#hasheq((Date . "Sun, 10 Sep 2017 09:48:44 +0200"))
#hasheq((Date . "Sun, 10 Sep 2017 13:16:19 +0200"))
#hasheq((Date . "Sun, 16 Oct 2011 23:12:02 -0500"))
#hasheq((Date . "Thu, 14 Sep 2017 12:03:35 -0700"))
#hasheq((Date . "Tue, 17 Nov 2009 18:04:31 -0800"))
#hasheq((Date . "Tue, 17 Nov 2009 18:21:38 -0500"))
#hasheq((Date . "Tue, 26 Oct 2010 15:11:06 +0200"))
#hasheq((Date . "Wed, 13 Sep 2017 10:40:47 -0700"))
#hasheq((Date . "Wed, 13 Sep 2017 17:51:05 +0000"))
#hasheq((Date . "Wed, 18 Nov 2009 02:22:12 -0800")))
As you can see, the dates are sorted alphabetically, not by date. Really, then, you need a #:key function that returns the date represented in a way that can easily be compared with other dates.
Your date strings are stored in a format called RFC-2822. I did a quick search of the Racket documentation and didn't find a standard library function to parse RFC-2822 date strings. Some googling turned up this blog post by Tero Hasu, which includes a function to convert RFC-2822 date strings into Unix times. A "Unix time" is a time represented as the number of seconds since January 1, 1970. That's a number, so you can compare it with <.
Here's the code pasted from Tero Hasu's blog:
(require (prefix-in s. srfi/19))
(define (rfc2822->unix-time s) ;; string -> integer
(let ((d (s.string->date s "~a, ~d ~b ~Y ~H:~M:~S ~z")))
(s.time-second (s.date->time-utc d))))
And finally, here's the corrected sort-mail:
(define (sort-mail hash-tables)
(define (ht->unix-time ht) (rfc2822->unix-time (hash-ref ht 'Date)))
(sort hash-tables #:key ht->unix-time <))
> (sort-mail test-hashes)
'(#hasheq((Date . "Tue, 17 Nov 2009 18:21:38 -0500"))
#hasheq((Date . "Tue, 17 Nov 2009 18:04:31 -0800"))
#hasheq((Date . "Wed, 18 Nov 2009 02:22:12 -0800"))
#hasheq((Date . "Tue, 26 Oct 2010 15:11:06 +0200"))
#hasheq((Date . "Sun, 16 Oct 2011 23:12:02 -0500"))
#hasheq((Date . "Mon, 17 Oct 2011 04:15:12 +0000"))
#hasheq((Date . "Sat, 09 Sep 2017 13:40:18 -0700"))
#hasheq((Date . "Sun, 10 Sep 2017 09:48:44 +0200"))
#hasheq((Date . "Sun, 10 Sep 2017 13:16:19 +0200"))
#hasheq((Date . "Mon, 11 Sep 2017 14:41:12 +0100"))
#hasheq((Date . "Wed, 13 Sep 2017 10:40:47 -0700"))
#hasheq((Date . "Wed, 13 Sep 2017 17:51:05 +0000"))
#hasheq((Date . "Thu, 14 Sep 2017 12:03:35 -0700")))