I have two columns containing dates.
I need to count how many times dates in column A are unequal to column B, and I want to be able to specify for which month I want it to count.
Have tried various versions of CountIF(s) and Sumproduct but have so far been unsuccessful - anyone got a suggestion?
=SUMPRODUCT(--(A1:A3<>B1:B3)) works for the counting, but not specific month.
A B C D
Actual Appoint. Month Count
03Feb18 03Feb18 February 2
10Feb18 15Feb18
18Feb18 15Feb18
Please try
=SUMPRODUCT((A2:A4<>B2:B4)*(TEXT(A2:A4,"mmmm")=C2))
This is for cases where the Actual month is February (the appointment could be March, say) - could be modified to count cases where one or both of actual and appointment fall in February.
Related
i want to count working days in a week by mentioned dates only like in picture only 4 working days will be considered in filtered data "year, month, and Week are derived by induction date column.Example
Do want that repeated dates are considered into the counting or not? Anyway, you could apply workday formula (=WORKDAY (start_date, days, [holidays])) in an additional column and count from there, adding or criteria with IF formula or other logic to exclude repeated dates if you do not want to consider them.
I have a Excel Master sheet where I am looking to query other sheets within the workbook. What I am trying to do is see How many occurrences of an ID for a Project in a column occur within a month, e.g. how many times does the ID 1367 occur in November. My dates are in the format of e.g 13/11/18 and this cannot be changed as I am just creating a report against a workbook I do not own.
The relevant columns I need are formatted like so:
Project: Project ID: Date:
a 123 1/01/2018
a 123 2/01/2019
a 123 3/01/2018
a 123
This is my SUMIFS function:
=SUMIF(PPlanner!$D:$D,Dashboard!$B$6,PPlanner!X:X)
This works by itself. My problem is trying to get the ID total for a specific month.
It returns the number of occurrences the ID occurs against a project all together but not against the month specifically. I have tried adding syntax to specify
the month but I am getting errors such as "too many arguments".
I recently answered a question that was very similar :
Excel - Take Average of Monthly Data
I think this would answer your question as well, but you have to use COUNTIFS instead of AVERAGEIFS
As for presentation, I would make a separate list of the months you want to include, and put the formula next to it, instead of the formula next to the actual list of data (as in the other question). As for how to write/input the month, you can put it any way you want, as long as it is a valid date in Excel. With the cell formatting you then can show it as month and year only. This is just to say that a text input JANUARY 2018 does not work (in a normal cell, eg. a cell that you did not format as text, when you type that into the cell, Excel recognizes this as a date, and will actually put 1/1/2018).
Oh, and using a Pivot table would work as well, the other answer on the question referenced above also explains how to do that.
In some cases, how Excel handles dates is very convenient.
For you, the date format doesn't matter. It is simply a number counting days with 0 being December 31st, 1899.
13/11/18 the date is the integer 43417 in-cell value. Excel interprets this as a both date and time together. The whole numbers are the days while the decimals are the time of day as a fraction of the day. 43417.5 would be noon.
So you may use COUNTIFS to help here.
=COUNTIFS(PPlanner!$X:$X, 1367, PPlanner!$D:$D, ">"&43404, PPlanner!$D:$D, "<"&43435)
This is going to look at sheet PPlanner column X and count how many instances of 1367 occur after the last day of October and before the first day of December. There are other ways to accomplish this, but it allows you to count within any date range you want.
I couldn't find a similar question that's why I asked a new one.
I have a worksheet with two columns - first column shows month and year in the following format "mon.year", for example "apr.2017" and the second one shows a number. The number must represent the count of some other dates filtered by specific criteria. I have those dates in another sheet - one column with name and one with a date.
What I want to do is count the number of dates for example from june 2017 from the second sheet and place the number in the second column in the first sheet.
Here is how the first sheet looks like:
And this is how the second sheet with data looks like:
The result I'm looking for is this:
So, I tried the following code but I can't figure out why it doesn't work.
Any suggestions how to improve the formula?
EDIT: So, both the comments below were helpful for me but as the formula had to be simplified at most (my colleagues work with the excel file, not me) I chose to calculate the month and year in two hidden columns, then use the countif formula on them.
You will need to bracket the dates:
=COUNTIFS('1'$B$2:$B$26,">=" & EOMONTH(A2,-1)+1,'1'$B$2:$B$26, "<" & EOMONTH(A2,0)+1)
For Excel, a date/time is just a formatted number, the number of days since a fixed epoch.
"="&MONTH(A2) is an expression which concatenates the string = with the result of the function MONTH(A2), which is 1. The result of the expression is =1, which is what COUNTIFS sees.
You're actually telling COUNTIFS to match the date/time whose serial number is 1 (December 31, 1999 at midnight). Similarly, the second criteria will match exactly on July 9, 1905 at midnight.
My suggestion for you is to compute the month and year of each date on separate columns, and use COUNTIFS on these columns.
I was wondering what would be a formula if I want to count based on various criteria, but specifically(because I think this is what I'm having trouble) if one of those criteria should be if a date of a column equals certain day of the week (i.e. 2/2/2016 = thursday)
So basically I want to count how many orders were made on a THURSDAY with the code FTN and with any status except ABANDONED (see image attachments)
Here is the formula I used which gave me 0 when the answer should be 5:
=COUNTIFS(A2:A15,WEEKDAY(A2:A15)=5,C2:C15,"FTN",D2:D15,"<>*ABANDONED*")
Data
Dates to day of week
COUNTIFS() is picky on how the criteria is done, you will not be able to do it this way. You will need to use an array type formula.
You can use SUMPRODUCT():
=SUMPRODUCT((WEEKDAY(A2:A15)=5)*(C2:C15="FTN")*(ISNUMBER(SEARCH("ABANDONED",D2:D15))))
This will count where all three are True.
Hopeful you can help me out.
I have an Excel spreadsheet open. The spreadsheet has two columns that I need assistance with.
The first column are dates and times that reflect a ticket that opened. The second column reflects dates and times that a ticket closed.
I am needing to correlate all the dates of which every ticket opened and closed to its respective week of the month. So if I have 20 tickets that opened up between the days of 2/22/15 - 2/28/15(all these dates are in the same column fyi...), then I will be needing to somehow correlate these tickets in my spreadsheet to some form of data to be used in a line stack chart.
An exec has laid this on my lap. I don't look useless and I would like a little assistance as to how to perform such a task. Formulas in Excel...Vlookup....or using Pivot Tables....please assist!
convert date in excel to its respective week of the month
in conjunction with the date range example:
=INT((DAY(A1)-1)/7)+1
In column 3 use the =Weeknum(A1, 1) formula to get the week number of the date in column a. The second argument lets you determine what you want for the beginning of the week to be.
In column 4 do the same for column b. This will give you the week ticket opened/closed respectively. Add column 5 to be the difference in weeks which can be used in a pivot table to show the distribution of tickets and weeks to resolve, etc.
Reply back if you have further needs.
Firstly get the week num of the first day of the month -1
A1 = 01/02/2018
B1 = =WEEKNUM(A1)-1
Then calculate the individiual ticket week numbers and take the week number before the first week of the month away from the returned value. You may need to format the cells as numbers as some reason Excel thinks its a date
Open Week = =WEEKNUM(OpenDateCell)-$B$1
Close Week = =WEEKNUM(CloseDateCell)-$B$1
Representative Image: