How to split strings based on special character (multiple times) - excel

Question

I'm trying to split a string based on ampersand (&), remove all the ampersands and separate each part to columns.
The number of strings differ every time.
Sample text:
My output:
What I need:
For i = 2 To 7
fullname = Cells(i, 1).Value
commaposition = InStr(fullname, "&")
Cells(i, 2).Value = Left(fullname, commaposition - 2)
For x = 2 To 7
fullname = Cells(i, 1).Value
commaposition = InStr(fullname, "&")
Cells(i, 3).Value = Mid(fullname, commaposition + 2)
Cells(x, 3).Value = Mid(fullname, commaposition + 2)
For y = 2 To 7
fullname = Cells(i, 1).Value
commaposition = InStr(fullname, "&")
Cells(i, 4).Value = Mid(fullname, commaposition + 2)
Cells(x, 4).Value = Mid(fullname, commaposition + 2)
Next y
Next x
Next i

Answer 1

Another option (other then #Storax's method) would be to use Regular Expressions which could account for more then just an ampersand.
Option Explicit
Public Sub FindNames()
Dim rng As Range
Dim j As Long
Dim c, Match
' Update for your range
With ActiveSheet
Set rng = .Range(.Cells(1, 1), .Cells(.Cells(.Rows.Count, 1).End(xlUp).Row, 1))
End With
With CreateObject("vbscript.regexp")
.Global = True
.Pattern = "\w+"
For Each c In rng
j = 0
If .test(c.Value2) Then
For Each Match In .Execute(c.Value2)
j = j + 1
c.Offset(0, j).Value2 = Match
Next Match
End If
Next c
End With
End Sub

Answer 2

You could try something like that
Sub SplitAmper()
Const AP = "&"
Dim v As Variant
Dim rg As Range
Set rg = Range("A2:A7") ' Adjust to your needs
Dim sngCell As Range
For Each sngCell In rg
v = Split(sngCell.Value, AP)
Cells(sngCell.Row, 1).Resize(, UBound(v) + 1) = v
Next
End Sub
Update: Another solution mentioned in the comments from SJR would be Text to Columns
Sub AnotherAmper()
Const AP = "&"
Dim rg As Range
Set rg = Range("A1:A7") ' Adjust to your needs
rg.TextToColumns Destination:=Range("B1"), DataType:=xlDelimited, _
Other:=True, OtherChar:=AP
End Sub