Finding Unique variables from CSV formatted text in a column - excel

Question

Column A contains the list of all counters and column D (onward) contains some related information which I'm extracting from form XML. Now I want to return those variables in column B for which there are multiple values in column D and beyond
For example:
for counter1, nothing should be returned
for counter2, "D" should be
returned as there are 2 unique values(4 and 5) for it
for counter3, "B,C,D" should be returned as there are multiple values for those 3 variables.
Format is standard, variable-value pairs are separated by comma and there is equal sign between variable and value, but there can be as many number of pairs and as many number of key pair instances(one counter can have up to 100+ such cells in front of them)

Answer 1

Going by the assumption that you want to
Search for multiple assignments to a variable of the form X=n and return all variable names that get assigned at least 2 different values. Multiple assignments within one cell are separated by a defined delimiter. A range of multiple cells that do or do not contain one or more assignments may serve as input.
The below function FindDuplicateAssignmentsInCSVRange(inputRange, listDelimiter, assignmentOperator accepts a range of cells and optionally allows to define an alternate list separator (default: comma) and an alternate assignment operator (default: equality symbol).
It outputs as a comma-separated list (or whatever alternate separator has been passed in) the names of all variables that get assigned at least 2 different values. If no variable name fulfills that requirement, an empty string is returned instead.
Option Explicit
Private Type TKeyValuePair
key As String
val As String
End Type
Private Function FindDuplicateAssignmentsInCSVRange(inpRange As Range, _
Optional ByVal listDelimiter As String = ",", _
Optional ByVal assingmentOperator As String = "=") As String
' this function needs a reference to the Microsoft Scripting Runtime to work
Const ReturnIndicator As String = "Return this value's key when done"
Dim dic As Scripting.Dictionary
Set dic = New Scripting.Dictionary
' Go into each cell in the given range
Dim c As Range
For Each c In inpRange.Cells
' split cell contents and iterate over each particle
Dim particle As Variant
For Each particle In Split(c.Value, listDelimiter)
' split each fragment "A=1" into variable and value; kvp = key-value pair
Dim kvp As TKeyValuePair
kvp.key = Split(particle, assingmentOperator)(0)
kvp.val = Split(particle, assingmentOperator)(1)
If Not dic.Exists(kvp.key) Then
' add new keys/variables to dictionary to keep track
dic.Add kvp.key, kvp.val
Else
' check values of existing keys and mark key if values differ ( = there are 2 or more different values)
Dim AlreadyMarkedForReturn As Boolean
AlreadyMarkedForReturn = (dic(kvp.key) = ReturnIndicator)
If dic(kvp.key) <> kvp.val And Not AlreadyMarkedForReturn Then
dic(kvp.key) = ReturnIndicator
End If
End If
Next particle
Next c
' clean up dictionary to only contain the return entries
Dim k As Variant
For Each k In dic.Keys
If dic(k) <> ReturnIndicator Then dic.Remove k
Next k
' return remaining keys as comma(or whatever)-separated list
FindDuplicateAssignmentsInCSVRange = Join(dic.Keys, listDelimiter)
End Function
Example usage:
Public Sub SO_51607467()
Debug.Print "D2:D2 Variables: '" & FindDuplicateAssignmentsInCSVRange(ThisWorkbook.Sheets(1).Range("D2")) & "'"
Debug.Print "D3:E3 Variables: '" & FindDuplicateAssignmentsInCSVRange(ThisWorkbook.Sheets(1).Range("D3:E3")) & "'"
Debug.Print "D4:F4 Variables: '" & FindDuplicateAssignmentsInCSVRange(ThisWorkbook.Sheets(1).Range("D4:F4")) & "'"
End Sub
Output of running SO_51607467 from within an approximate (due to copy-typing) copy of the workbook you showed:
D2:D2 Variables: ''
D3:E3 Variables: 'D'
D4:F4 Variables: 'B,C'