Calculate y from x for a single label - gnuplot

Question

I want to manually add a label in the graph at a certain x position by only entering x and calculate y from the datapoint.
e.g.:
1 set terminal png
2 set output 'test2.png'
3
4 x = 3
5 y = 33
6 set label "test" at x,y
7
8 plot '-' using 1:2 with lines
9 1 11
10 2 22
11 3 33
12 4 22
13 5 33
So, I don't want to hardcode "33" in line 5.
Is that possible?
(I have googled this question and inspected the possible duplicates offered by Stackoverflow after I entered the title. Nada.)

Answer 1

Method 1 (data scan)
For not too-large inputs, one could load the x/y data into two separate arrays and then locate the y-value corresponding to a given x-value:
$DATA <<EOD
1 11
2 22
3 33
4 22
5 33
EOD
stat $DATA nooutput
N = STATS_records
array data_x[N]
array data_y[N]
stat $DATA u (data_x[1+$0]=$1,data_y[1+$0]=$2,$1):2 nooutput
x0 = 3
y0 = NaN
do for [i=1:N] {
if (data_x[i] == x0) {
y0 = data_y[i]
}
}
set label "test" at x0,y0
plot $DATA using 1:2 with lines t ''
The trick here is the second stat command which is used solely in order to populate the arrays data_x, and data_y. The expression (data_x[1+$0]=$1,data_y[1+$0]=$2,$1):2 basically evaluates for each row in the data to 1:2. However, due to the comma operator, it has the side effect of setting the corresponding elements of data_x, and data_y.
Method 2 (fitting)
As an approximate alternative, one might fit a narrow Gaussian centered at x0 = 3 to the input data set. If the characteristic width sigma of this Gaussian is smaller than the characteristic spacing between data points, then the amplitude should match the input y-value:
$DATA <<EOD
1 11
2 22
3 33
4 22
5 33
EOD
x0 = 3
sigma = 0.1
f(x) = a*exp(-(x - x0)**2 / (2*sigma**2))
fit f(x) $DATA using 1:2 via a
print a
y0 = a
set label "test" at x0,y0
plot $DATA using 1:2 with lines t ''
Method 3 (external tool)
As a more robust alternative, one could delegate this task to an external utility invoked in Gnuplot via the system call. The example is using gawk to scan the input data file. If it finds a matching value in the first column, it prints the corresponding y value and exits (so that only the first occurence is reported):
inputFileName = 'data.txt'
x0 = 3
getY(fName, x) = system(sprintf("gawk '$1==%d{print $2;exit}' '%s'", x, fName))
y0 = getY(inputFileName, 3)
set label "test" at x0,y0
plot inputFileName using 1:2 with lines t ''

Answer 2

You say "manually", so maybe interactive placement is an option? A mouse click on the desired location will load variables MOUSE_X and MOUSE_Y, which can then be used to generate a label. There is a demo "mouselabels.dem" in the distribution that automates this and might be informative, but in essence you would do
plot FOO # initial plot with no labels
pause mouse # wait for mouse click
set label 1 "test" at MOUSE_X, MOUSE_Y
replot # same plot with a label at the requested position