Comparing unbounded strings in Ada - string

Question

Hello I am confronted with the predicament of comparing two unbounded strings in Ada and arrange the set of data values in a sorted fashion using the names (strings) as keys. I am at an absolute loss to determine how to compare two strings in ada or more precisely to determine which one comes first in an ascending order.
with Ada.Text_IO;
with Ada.Integer_Text_IO;
with Ada.Unchecked_Deallocation;
with Ada.Strings.Unbounded; use Ada.Strings.Unbounded;
with Ada.Text_IO.Unbounded_IO; use Ada.Text_IO.Unbounded_IO;
procedure Main is
package TIO renames Ada.Text_IO;
package IIO renames Ada.Integer_Text_IO;
Name_Main1, Name_Main2, Name_Main3 : Ada.Strings.Unbounded.Unbounded_String;
begin
TIO.Put_Line("Enter the Name of the student :");
Ada.Text_IO.Unbounded_IO.Get_Line(Name_Main1);
TIO.Put_Line("Enter the Name of the student :");
Ada.Text_IO.Unbounded_IO.Get_Line(Name_Main2);
TIO.Put_Line("Enter the Name of the student :");
Ada.Text_IO.Unbounded_IO.Get_Line(Name_Main3);
if Name_Main1 > Name_Main2 then
TIO.Put_Line("Some semblance");TIO.New_Line;
else
TIO.Put_Line("Cant be matched");
end if;
end Main;
More it does not help in any way that most of these strings are of varying length. I am of a C background so looking for a strcmp kind of a functionality.
Please help if you can. There is very less or no documentation regarding this important feature on the net for Ada.

Answer 1

Ada Reference Manual
For Unbounded_String:
http://www.adaic.org/resources/add_content/standards/12rm/html/RM-A-4-5.html
83
Each of the functions "=", "<", ">", "<=", and ">=" returns the same result as the corresponding String operation applied to the String values given or represented by Left and Right.
For String literals:
http://www.adaic.org/resources/add_content/standards/12rm/html/RM-3-6-3.html
5
54 String literals (see 2.6 and 4.2) are defined for all string types. The concatenation operator & is predefined for string types, as for all nonlimited one-dimensional array types. The ordering operators <, <=, >, and >= are predefined for string types, as for all one-dimensional discrete array types; these ordering operators correspond to lexicographic order (see 4.5.2).
For one-dimensional array types:
http://www.adaic.org/resources/add_content/standards/12rm/html/RM-4-5-2.html
26/3
For a discrete array type, the predefined ordering operators correspond to lexicographic order using the predefined order relation of the component type: A null array is lexicographically less than any array having at least one component. In the case of nonnull arrays, the left operand is lexicographically less than the right operand if the first component of the left operand is less than that of the right; otherwise, the left operand is lexicographically less than the right operand only if their first components are equal and the tail of the left operand is lexicographically less than that of the right (the tail consists of the remaining components beyond the first and can be null).
Examples:
37
"" < "A" and "A" < "Aa" -- True
"Aa" < "B" and "A" < "A " -- True
If you need to sort Unbounded_Strings, you can use Containers.Generic_Array_Sort:
with Ada.Strings.Unbounded; use Ada.Strings.Unbounded;
with Ada.Text_IO; use Ada.Text_IO;
with Ada.Text_IO.Unbounded_IO; use Ada.Text_IO.Unbounded_IO;
with Ada.Containers.Generic_Array_Sort;
procedure Main is
Name_Main1, Name_Main2, Name_Main3 : Unbounded_String :=
Null_Unbounded_String;
begin
Put_Line ("Enter the Name of the student :");
Get_Line (Name_Main1);
Put_Line ("Enter the Name of the student :");
Get_Line (Name_Main2);
Put_Line ("Enter the Name of the student :");
Get_Line (Name_Main3);
declare
-- Array of Unbounded_Strings
type Unbarr is array (Positive range <>) of Unbounded_String;
-- Sort procedure
procedure Unbsort is new Ada.Containers.Generic_Array_Sort
(Positive, Unbounded_String, Unbarr, "<");
-- Array of Unbounded_Strings
Z : Unbarr := Name_Main1 & Name_Main2 & Name_Main3;
begin
-- Sort array
Unbsort (Z);
-- Output sorted array
Put_Line ("Sorted:");
for X of Z loop
Put_Line (X);
end loop;
end;
end Main;.