Search from Excel combobox, returing results to userform - excel

Question

I'd like search from a combobox on a userform, returning 2 items from 2 different rows. So far I am using a predetermined location set to return the alternate rows.
My question is about this section:
Private Sub ComboBox1_Change()
If ComboBox1.Text = Sheet1.Cells(3, 1) Then
oHousing.Text = Sheet1.Cells(3, 2)
oMeal.Text = Sheet1.Cells(3, 3)
End If
End Sub
Here is what the pseudocode would do:
User selects item in combobox
combobox will search A1:A99 for item
then once item is found it will output B# and C# (# is based on location of A#)
B# is outputted to oHousing (textbox)
C# is outputted to oMeal (textbox)
On my sheet I have:
A2:A28 with random text (I used ABC's)
B2:B28 are random 3 digit numbers (numeric, eg: 001-999)
C2:C28 is Random 3 numbers (numeric, eg: 001-999)
Here's the rest of my code:
'Finds the difference in 2 known dates (returns whole number in textbox)
Private Sub CommandButton1_Click()
Dim firstDate As Date, secondDate As Date, n As Integer
firstDate = DateValue(sDate.Text)
secondDate = DateValue(EDate.Text)
n = DateDiff("d", firstDate, secondDate) - 0.5
dTotal.Text = n
End Sub
Private Sub CommandButton2_Click() 'Exit the userform (PerDiem)
Unload PerDiem
End Sub
Thanks to all in advance!

Answer 1

You can use the Find function.
If a value is found, you can return the Row Number with Found.Row and Column Index with Count.Column
Private Sub ComboBox1_Change()
Dim Found As Range
Set Found = Sheet1.Range("A1:A99").Find(ComboBox1.Text, , xlValues, xlWhole)
If Found Is Nothing Then
'What do you want to do if your value in CommboBox is not found in the range?
Else
oHousing.Text = Sheet1.Cells(Found.Row, 2)
oMeal.Text = Sheet1.Cells(Found.Row, 3)
End If
End Sub
If you are sure that your ComboBox value will always exist in your range (maybe you systematically programmed your ComboBox values this way) you can skip the check and simply use:
Dim Found As Range
Set Found = Sheet1.Range("A1:A99").Find(ComboBox1.Text, , xlValues, xlWhole)
oHousing.Text = Sheet1.Cells(Found.Row, 2)
oMeal.Text = Sheet1.Cells(Found.Row, 3)
You can find properties of the Find method here. If you are looking for text, you may need to distinguish between case sensitivity (for your needs, does THIS = this?). The properties that are currently applied means the function is looking for values (xlValues), specifically, looking at the whole value of the cell (xlWhole). I.E. (this value will not match with this)